Могу ли я использовать гиперссылку для запуска макроса vba в Excel?

Это сработает для вас

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
        MsgBox "Row " & ActiveCell.Row & " is clicked"
End Sub

Да, вы можете, для этого выполните следующие простые шаги:

1. Выберите ячейку, в которой вы хотите сделать гиперссылку
2. Щелкните правой кнопкой мыши - ›Гиперссылка…
3. Введите адрес той же ячейки, в которой вы делаете гиперссылку, и дайте имя ссылке. См. Картинку ниже:

Назначить макрос гиперссылке

4. Щелкните ОК.
5. Гиперссылка создана.

Примечание. Щелчок по этой гиперссылке ничего не сделает, потому что она назначена тому же адресу ячейки.

6. Теперь нажмите Alt + F11
7. Скопируйте и вставьте приведенный ниже код

Запустите макрос Excel, щелкнув гиперссылку

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)  
    'Check if the Target Address is same as you have given  
    'In the above example i have taken A4 Cell, so I am  
    'Comparing this with $A$4  
  
    If Target.Range.Address = "$A$4" Then  
        'Write your all VBA Code, which you want to execute  
        'Or Call the function or Macro which you have  
        'written or recorded.  
        MsgBox "Write your Code here to be executed"  
        Exit Sub  
    End If  
End Sub  

В приведенном выше коде мы сравниваем адрес ячейки, а затем выполняем набор кода или функции. Есть и другой способ сделать это. Мы можем сравнить с целевым именем и выполнить код. В приведенном выше примере я дал имя цели гиперссылки как MyMacro.

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)  
    'Check if the Target Name is same as you have given  
    'In the above example i have given the Name of the HyperLink  
    'is MyMacro.  
  
    If Target.Name = "mymacro" Then  
        'Write your all VBA Code, which you want to execute  
        'Or Call the function or Macro which you have  
        'written or recorded.  
        MsgBox "Write your Code here to be executed"  
        Exit Sub  
    End If  
End Sub  

Следующий подход (формула гиперссылки) - более интересный способ запуска макроса с помощью гиперссылки. Не нужно никаких событий:

1. Напишите формулу гиперссылки в ячейку. Это можно сделать и в VBA:

    Sub testCreateHyperlinkFunction()
       'Very important to have # in front of the function name!
       Range("A1:A5").Formula = "=HYPERLINK(""#MyFunctionkClick()"", ""Run a function..."")"
    End Sub

Более эффектным будет следующий подход, способный сохранить начальное значение ячеек обрабатываемого диапазона (в примере A1: A5):

Sub testCreateHyperlinkFunctionBis()
  Dim rng As Range, arr As Variant, c As Range, i As Long
   Set rng = Range("A1:A5")
   arr = rng.Value
   For i = 1 To UBound(arr, 1)
     Range("A" & i).Formula = "=HYPERLINK(""#MyFunctionkClick()"", " & _
            IIf(IsNumeric(arr(i, 1)), arr(i, 1), """" & arr(i, 1) & """") & ")"
   Next i
End Sub

2. Создайте функцию для вызова (в модуле):

    Function MyFunctionkClick()
      Set MyFunctionkClick = Selection 'Do not miss this part!
      MsgBox "The clicked cell addres is " & Selection.row
    End Function

3. Щелчком по ячейке запускается функция MyFunctionkClick() ...

Я просто хотел бы добавить еще один подход, основанный на одном из ответов здесь, который я использовал в прошлом. Это означает, что вам не нужно создавать гиперссылки или вспомогательный столбец, чтобы начать обработку строки, вы можете просто дважды щелкнуть любую ячейку в строке, которую хотите обработать:

На листе, на котором вы хотите выполнить двойной щелчок, используйте это:

Private Sub Worksheet_Activate()
Application.OnDoubleClick = "Module1.ProcessRow"
End Sub

Private Sub Worksheet_Deactivate()
Application.OnDoubleClick = ""
End Sub

А затем в Module1 есть процедура, которая будет обрабатывать активную ячейку:

Sub processRow()
MsgBox "Row " & ActiveCell.Row & " on " & ActiveSheet.Name & " was clicked"
End Sub

Вам также следует отключить метод двойного щелчка в Excel в событиях книги:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Application.OnDoubleClick = ""
End Sub

Я считаю, что метод двойного щелчка действительно очень удобен и интуитивно понятен для многих процессов, например. создание UserForm с данными, заполненными из строки, или перенос этих данных на другой лист, возможно, с помощью вычислений или форматирования и т. д.

Я думаю, что вместо того, чтобы создавать гиперссылку для каждой ячейки, лучше создать макрос, который ссылается на свойство Activecell. Затем создайте сочетание клавиш для запуска макроса. Для этого:

1. Нажмите ALT + F8
2. Выберите Options
3. Выберите клавишу, которая будет сочетанием клавиш

Если у вас уже есть гиперссылки, лучше всего запустить макрос с помощью события Hyperlink_Follow. Если нет, то учтите мою рекомендацию.