Прокрутка Vim без изменения положения курсоров на экране

Если вы хотите переместить курсор и область просмотра вместе с курсором в любом месте экрана, возможно, вам следует настроить некоторые пользовательские привязки клавиш, чтобы выполнять и то и другое одновременно.

Такие как:

:nnoremap <C-M-u> j<C-e>

Это будет перемещать курсор вниз (j) и перемещать область просмотра (Ctrl-e) всякий раз, когда вы нажимаете Ctrl-Alt-u (только в обычном режиме).

Я могу думать о двух способах: ctrl - E и ctrl - Y прокручивать буфер, не перемещая положение курсора относительно окна. Я думаю, это то, что ты хочешь. Кроме того, если вы установите для scrolloff большое число, вы получите тот же эффект, что и ctrl - E и ctrl - Y < / kbd> клавишами перемещения. scrolloff, однако, затруднит перемещение курсора по вертикали относительно окна. (Используйте что-то вроде :set so=999, so - сокращение от scrolloff.)

:help 'scrolloff'
:help scrolling

ctrl - D и ctrl - U - это то, что вы хотите.

ctrl - D имеет тот же эффект, что и 14j14<C-e> (просто число 14 не жестко запрограммировано, а количество движения зависит от фактического размера вашего экрана): вы перемещаетесь курсор на несколько строк ниже в тексте, но курсор остается в середине экрана.

Аналогично ctrl - U работает как 14k14<C-y>.

Дополнение: если на вашем экране 30 строк, то эти две абсолютно одинаковые.

Попробуйте это сопоставление в .vimrc

map <ScrollWheelUp>   5<C-Y>
map <ScrollWheelDown> 5<C-E>

Я знаю два метода. Добавьте эти строки в свой файл .vimrc (выбрав только один из двух методов):

Способ 1:

function! s:GetNumScroll(num)
  let num_rows = winheight(0)
  let num_scroll = a:num
  if (a:num == -1)
    let num_scroll = (num_rows + 1) / 2
  elseif (a:num == -2)
    let num_scroll = num_rows
  endif
  if (num_scroll < 1)
    let num_scroll = 1
  endif
  return num_scroll
endfunction

function! s:RtrnToOrig(before_scr_line)
  normal H
  let delta = a:before_scr_line - winline()
  while (delta != 0)
    if (delta < 0)
      let delta = winline() - a:before_scr_line
      let iter = 1
      while (iter <= delta)
        execute "normal" "gk"
        let iter +=1
      endwhile
    elseif (delta > 0)
      let iter = 1
      while (iter <= delta)
        execute "normal" "gj"
        let iter +=1
      endwhile
    endif
    let delta = a:before_scr_line - winline()
  endwhile
endfunction

function! s:scrollUP(num)
  let num_scroll = <SID>GetNumScroll(a:num)
  let num_rows = winheight(0)
  " -------------
  let before_scr_line = winline()
  normal L
  let after_scr_line = winline()
  let extra = num_rows - after_scr_line
  let extra += num_scroll
  " move by 1 to prevent over scrolling
  let iter = 1
  while (iter <= extra)
    execute "normal" "gj"
    let iter +=1
  endwhile
  " -------------
  call <SID>RtrnToOrig(before_scr_line)
endfunction

function! s:scrollDN(num)
  let num_scroll = <SID>GetNumScroll(a:num)
  " -------------
  let before_scr_line = winline()
  normal H
  let after_scr_line = line(".")
  execute "normal" "gk"
  let after_scr2_line = line(".")
  if ( (after_scr_line == after_scr2_line) && (after_scr_line > 1) )
    execute "normal" "gk"
  endif
  let extra = (num_scroll - 1)
  let extra += (winline() - 1)
  " move by 1 to prevent over scrolling
  let iter = 1
  while (iter <= extra)
    execute "normal" "gk"
    let iter +=1
  endwhile
  " -------------
  call <SID>RtrnToOrig(before_scr_line)
endfunction

 nmap <silent> <C-J>     :call <SID>scrollUP(1)<CR>
 nmap <silent> <C-K>     :call <SID>scrollDN(1)<CR>
 nmap <silent> <C-F>     :call <SID>scrollUP(-1)<CR>
 nmap <silent> <C-B>     :call <SID>scrollDN(-1)<CR>
 nmap <silent> <PageDown>:call <SID>scrollUP(-2)<CR>
 nmap <silent> <PageUp>  :call <SID>scrollDN(-2)<CR>

При этом используются обычные H, L для перехода к началу экрана, bot и команды gk, gj для перемещения вверх, вниз по строке экрана вместо фактической строки. Это сложнее, чем казалось бы, просто для правильной работы, когда строки длиннее ширины экрана и включен перенос слов.

Или этот метод (который ранее был опубликован в вики-странице подсказок vim и на Stack Exchange):

Способ 2:

" N<C-D> and N<C-U> idiotically change the scroll setting
function! s:Saving_scrollV(cmd)
  let save_scroll = &scroll
  execute "normal" a:cmd
  let &scroll = save_scroll
endfunction

" move and scroll
 nmap <silent> <C-J>           :call <SID>Saving_scrollV("1<C-V><C-D>")<CR>
 vmap <silent> <C-J> <Esc>     :call <SID>Saving_scrollV("gv1<C-V><C-D>")<CR>
 nmap <silent> <C-K>           :call <SID>Saving_scrollV("1<C-V><C-U>")<CR>
 vmap <silent> <C-K> <Esc>     :call <SID>Saving_scrollV("gv1<C-V><C-U>")<CR>

 nmap <silent> <C-F>           :call <SID>Saving_scrollV("<C-V><C-D>")<CR>
 vmap <silent> <C-F> <Esc>     :call <SID>Saving_scrollV("gv<C-V><C-D>")<CR>
 nmap <silent> <PageDown>      :call <SID>Saving_scrollV("<C-V><C-D>")<CR>
 vmap <silent> <PageDown> <Esc>:call <SID>Saving_scrollV("gv<C-V><C-D>")<CR>

 nmap <silent> <C-B>           :call <SID>Saving_scrollV("<C-V><C-U>")<CR>
 vmap <silent> <C-B> <Esc>     :call <SID>Saving_scrollV("gv<C-V><C-U>")<CR>
 nmap <silent> <PageUp>        :call <SID>Saving_scrollV("<C-V><C-U>")<CR>
 vmap <silent> <PageUp> <Esc>  :call <SID>Saving_scrollV("gv<C-V><C-U>")<CR>

Единственная проблема, с которой я сталкиваюсь со вторым методом, - это когда строки длиннее ширины экрана и включен перенос слов, тогда курсор может перемещаться вверх или вниз, чтобы учесть дополнительные строки из переноса. Также курсор может перемещаться вверху и внизу файла. Первый метод действительно пытается никогда не перемещать курсор во всех случаях.

Это изменяет положение курсора на экране, но не меняет положение строки курсора на экране:

noremap <C-k> @="1\<lt>C-D>"<CR>:set scroll=0<CR>
noremap <C-l> @="1\<lt>C-U>"<CR>:set scroll=0<CR>

Однако это сбрасывает параметр scroll, поэтому последующие <C-D> и <C-U> будут прокручиваться на половину экрана. Без set scroll=0 параметр scroll был бы установлен в 1, а последующие <C-D> и <C-U> прокручивались бы на одну строку (Vim странный).

Вероятно, лучше всего подойдет функция Vimscript, основанная на 1<C-D> и 1<C-U>.