Как я могу предотвратить столкновение / взаимодействие ярлыков в Delphi?

Хорошо, первое, что нужно сделать: это не имеет ничего общего с модальными или немодальными формами, это ограничение того, как работают компоненты действий Delphi (если вы хотите это так называть).

Позвольте мне доказать это на простом примере: создайте новое приложение с новой формой, поместите на него TMemo и TComboBox и запустите приложение. Оба элемента управления будут иметь системное контекстное меню с командами редактирования и будут правильно на них реагировать. Они будут делать то же самое для ярлыков меню, за исключением Ctrl + A, который не поддерживается для поля со списком.

Теперь добавьте TActionList компонент с тремя стандартными действиями: «Вырезать», «Копировать» и «Вставить». Дела по-прежнему будут работать, в поведении никаких изменений.

Теперь добавьте главное меню и добавьте меню «Правка» из шаблона. Удалите все команды, кроме «Вырезать», «Копировать» и «Вставить». Установите соответствующие компоненты действия для пунктов меню и запустите приложение. Обратите внимание на то, что в поле со списком все еще есть контекстное меню, и команды там все еще работают, но ярлыки больше не работают.

Проблема в том, что стандартные действия редактирования были разработаны для работы только с TCustomEdit элементами управления. Взгляните на метод TEditAction.HandlesTarget() в StdActns.pas. Так как элементы управления редактированием в полях со списком, встроенные редакторы в элементах управления в виде дерева или элементы управления редактированием в собственных диалоговых окнах не улавливаются этим, они не будут обрабатываться. Команды меню всегда будут отключены, если один из этих элементов управления находится в фокусе. Что касается ярлыков, работающих только некоторое время - это зависит от того, отображает ли VCL в какой-то момент ярлыки на команды действия или нет. Если этого не произойдет, они наконец достигнут собственной оконной процедуры и инициируют команду редактирования. В этом случае ярлыки будут работать. Я предполагаю, что для модальных диалогов обработка действий приостановлена, поэтому поведение модальных и немодальных диалогов различается.

Чтобы обойти это, вы можете предоставить обработчики для OnExecute этих стандартных действий. Например, для команды Вставить:

procedure TMainForm.EditPaste1Execute(Sender: TObject);
var
  FocusWnd: HWND;
begin
  FocusWnd := GetFocus;
  if IsWindow(FocusWnd) then
    SendMessage(FocusWnd, WM_PASTE, 0, 0);
end;

и аналогичные обработчики для команды «Вырезать» (WM_CUT) и команды «Копировать» (WM_COPY). Выполнение этого в небольшом демонстрационном приложении заставит снова работать для поля со списком. Вы должны попробовать в своем приложении, но я полагаю, это поможет. Сложнее правильно включить и отключить команды главного меню для всех встроенных элементов управления редактированием. Возможно, вы могли бы отправить сообщение EM_GETSEL, чтобы проверить, есть ли выделение в элементе управления сфокусированным редактированием.

Изменить:

Подробнее, почему поведение полей со списком в модальных и немодальных диалогах различается (анализ выполнен в Delphi 2009): интересный код находится в TWinControl.IsMenuKey() - он пытается найти компонент действия в одном из списков действий родительской формы сфокусированного элемента управления, который обрабатывает ярлык. Если это не удается, он отправляет сообщение CM_APPKEYDOWN, что в конечном итоге приводит к той же проверке, выполняемой со списками действий главной формы приложения. Но вот в чем дело: это будет сделано только в том случае, если включен дескриптор окна главной формы приложения (см. Код TApplication.IsShortCut()). Теперь вызов ShowModal() в форме отключит все другие формы, поэтому, если модальное диалоговое окно не содержит самого действия с тем же ярлыком, собственная обработка ярлыков будет работать.

Изменить:

Я мог бы воспроизвести проблему - ключ в том, чтобы каким-то образом отключить действия редактирования. Оглядываясь назад, это очевидно, свойство Enabled действий, конечно же, тоже нуждается в обновлении.

Попробуйте использовать этот дополнительный обработчик событий:

procedure TForm1.ActionList1Update(Action: TBasicAction; var Handled: Boolean);
var
  IsEditCtrl, HasSelection, IsReadOnly: boolean;
  FocusCtrl: TWinControl;
  FocusWnd: HWND;
  WndClassName: string;
  SelStart, SelEnd: integer;
  MsgRes: LRESULT;
begin
  if (Action = EditCut1) or (Action = EditCopy1) or (Action = EditPaste1) then
  begin
    IsEditCtrl := False;
    HasSelection := False;
    IsReadOnly := False;

    FocusCtrl := Screen.ActiveControl;
    if (FocusCtrl <> nil) and (FocusCtrl is TCustomEdit) then begin
      IsEditCtrl := True;
      HasSelection := TCustomEdit(FocusCtrl).SelLength > 0;
      IsReadOnly := TCustomEdit(FocusCtrl).ReadOnly;
    end else begin
      FocusWnd := GetFocus;
      if IsWindow(FocusWnd) then begin
        SetLength(WndClassName, 64);
        GetClassName(FocusWnd, PChar(WndClassName), 64);
        WndClassName := PChar(WndClassName);
        if AnsiCompareText(WndClassName, 'EDIT') = 0 then begin
          IsEditCtrl := True;
          SelStart := 0;
          SelEnd := 0;
          MsgRes := SendMessage(FocusWnd, EM_GETSEL, WPARAM(@SelStart),
            LPARAM(@SelEnd));
          HasSelection := (MsgRes <> 0) and (SelEnd > SelStart);
        end;
      end;
    end;

    EditCut1.Enabled := IsEditCtrl and HasSelection and not IsReadOnly;
    EditCopy1.Enabled := IsEditCtrl and HasSelection;
    // don't hit the clipboard three times
    if Action = EditPaste1 then begin
      EditPaste1.Enabled := IsEditCtrl and not IsReadOnly
        and Clipboard.HasFormat(CF_TEXT);
    end;
    Handled := TRUE;
  end;
end;

Я не проверял, является ли встроенный элемент управления редактированием доступным только для чтения, это, вероятно, можно сделать, добавив следующее:

IsReadOnly := GetWindowLong(FocusWnd, GWL_STYLE) and ES_READONLY <> 0;

Примечание. Я дал ответ Мги, поскольку он проделал большую работу и его ответ правильный, но я реализовал более простое решение, которое я сам добавил в качестве ответа

Я разместил ссылку на этот вопрос в своем блоге и получил предложение от Уве Молжан, которого нет на StackOverflow. Uwe раньше запускал DelphiPool. Он указал мне на эту ветку на borland.public.delphi.objectpascal:

Список действий (неправильное) поведение .

Том Александр, задавший первоначальный вопрос в этой ветке, даже сказал:

Такое поведение наблюдается обычно, но не всегда. Иногда после серии вышеуказанных ошибок поведение начинает действовать так, как я ожидал.

это именно то странное поведение, которое у меня было, что сделало эту проблему почти невозможной для отслеживания.

Питер Белов ответил в этой беседе, что если есть конфликтующие ярлыки, вы должны предпринять шаги, чтобы активный элемент управления первым взломал ярлык.

Взяв его код (который был написан для проблемы с фреймами), мне просто пришлось изменить «ctrl is TCustomFrame» на «ctrl is TControl», и он отлично работает. Итак, вот что было необходимо:

public
Function IsShortcut( var Message: TWMKey): Boolean; override;

Function TMyform.IsShortcut( var Message: TWMKey): Boolean; 
Var 
  ctrl: TWinControl; 
  comp: TComponent; 
  i: Integer; 
Begin 
  ctrl := ActiveControl; 
  If ctrl <> Nil Then Begin 
    Repeat 
      ctrl := ctrl.Parent 
    Until (ctrl = nil) or (ctrl Is TControl); 
    If ctrl <> nil Then Begin 
      For i:= 0 To ctrl.componentcount-1 Do Begin 
        comp:= ctrl.Components[i]; 
        If comp Is TCustomActionList Then Begin 
          result := TCustomActionList(comp).IsShortcut( message ); 
          If result Then 
            Exit; 
        End; 
      End;   
    End; 
  End; 
//  inherited; { Originally I had this, but it caused multiple executions }
End;   

Пока что это работает для меня во всех случаях.

По иронии судьбы, это не сработало с Томом Александром, который изначально задавал вопросы. Вместо этого он добавил процедуру к событию FrameEnter, которая устанавливает фокус на соответствующую сетку для кадра. Это может означать еще одно альтернативное решение моего вопроса, но мне нет необходимости исследовать это, поскольку решение Питера работает для меня.

Также обратите внимание, что Питер включает в свой ответ превосходное резюме сложных шагов обработки ключей, которое стоит знать.

Но теперь я хочу проверить правку Мги на его ответ и посмотреть, является ли это также решением.

Я создал очень простой пример с двумя формами в Delphi 2009 (установлены обновления 3 и 4), работающих в 64-разрядной версии Vista. Вторая форма, Form2, отображается в немодальном режиме (Form2.Show;). У меня есть TMemo на Form2. Ctrl-X, Ctrl-V и Ctrl-C работают нормально.

Это было до того, как я разместил TMainMenu в Form2.

Итак, я поместил TMainMenu в форму и добавил TActionList. Я создаю пункты меню «Правка» и добавляю элементы подменю «Копировать», «Вырезать», «Вставить». Я подключил их к стандартным действиям EditCopy, EditCut и EditPaste. Тем не менее, все работает нормально, как и раньше. Я могу использовать либо пункты меню, либо комбинации клавиш Ctrl-C, Ctrl-X и Ctrl-V.

Здесь должно быть что-то еще.