В Delphi чтение в TList‹x› потокобезопасно?

Я создал простой класс ведения журнала и хочу убедиться, что он потокобезопасен. В основном Log, RegisterLogger и UnRegisterLogger будут вызываться из разных потоков. Log будет вызываться часто (из многих разных потоков), а RegisterLogger и UnRegisterLogger редко.

По сути, мой вопрос можно свести к следующему: «Являются ли чтения в TList<x> потокобезопасными?», то есть могу ли я одновременно иметь несколько потоков, обращающихся к TList.

IExecutionCounterLogger — это интерфейс с методом Log (с той же сигнатурой, что и TExecutionCounterServer.Log)

Type
  TExecutionCounterServer = class
  private
    Loggers : TList<IExecutionCounterLogger>;
    Synchronizer : TMultiReadExclusiveWriteSynchronizer;
  public
    procedure RegisterLogger(Logger : IExecutionCounterLogger);
    procedure UnRegisterLogger(Logger : IExecutionCounterLogger);
    procedure Log(const ClassName, MethodName : string; ExecutionTime_ms : integer);

    constructor Create;
    destructor Destroy; override;
  end;

constructor TExecutionCounterServer.Create;
begin
  Loggers := TList<IExecutionCounterLogger>.Create;
  Synchronizer := TMultiReadExclusiveWriteSynchronizer.Create;
end;

destructor TExecutionCounterServer.Destroy;
begin
  Loggers.Free;
  Synchronizer.Free;
  inherited;
end;

procedure TExecutionCounterServer.Log(const ClassName, MethodName: string; ExecutionTime_ms: integer);
var
  Logger: IExecutionCounterLogger;
begin
  Synchronizer.BeginRead;
  try
    for Logger in Loggers do
      Logger.Log(ClassName, MethodName, ExecutionTime_ms);
  finally
    Synchronizer.EndRead;
  end;
end;

procedure TExecutionCounterServer.RegisterLogger(Logger: IExecutionCounterLogger);
begin
  Synchronizer.BeginWrite;
  try
    Loggers.Add(Logger);
  finally
    Synchronizer.EndWrite;
  end;
end;

procedure TExecutionCounterServer.UnRegisterLogger(Logger: IExecutionCounterLogger);
var
  i : integer;
begin
  Synchronizer.BeginWrite;
  try
    i := Loggers.IndexOf(Logger);
    if i = -1 then
      raise Exception.Create('Logger not present');
    Loggers.Delete(i);  
  finally
    Synchronizer.EndWrite;
  end;
end;

В качестве дополнительной информации это следует из этого вопроса. По сути, я добавил некоторый инструментарий к каждому методу (DCOM) сервера DataSnap, а также подключился к каждому событию TDataSnapProvider OnGetData и OnUpdateData.