Разделение данных конфигурации и логики сценария в сценариях Perl

Мне больше всего нравится Config::Std. Мне нравится, как он обрабатывает многострочный и составные значения конфигурации.

Вы должны быть осторожны, когда переменная потенциально многозначна: если в файле конфигурации существует одно значение, оно будет храниться в скаляре; если существует несколько значений, вы получите ссылку на массив.

Я считаю удобным иметь два файла конфигурации: один для значений, описывающих операционную среду (где найти библиотеки и т. д.), а другой — для изменяемого пользователем поведения.

Я также люблю писать обертку вокруг него. Например (обновлено для включения автоматически созданных средств доступа только для чтения):

#!/usr/bin/perl

package My::Config;
use strict; use warnings;

use Config::Std;
use FindBin qw($Bin);
use File::Spec::Functions qw( catfile );

sub new {
    my $class = shift;
    my ($config_file) = @_;

    $config_file = catfile($Bin, 'config.ini');
    read_config $config_file => my %config;

    my $object = bless \%config => $class;

    $object->gen_accessors(
        single => {
            install => [ qw( root ) ],
        },
        multi => {
            template => [ qw( dir ) ],
        },
    );

    return $object;
}

sub gen_accessors {
    my $config = shift;
    my %args = @_;

    my $class = ref $config;

    {
        no strict 'refs';
        for my $section ( keys %{ $args{single} } ) {
            my @vars = @{ $args{single}->{$section} };
            for my $var ( @vars ) {
                *{ "${class}::${section}_${var}" } = sub {
                    $config->{$section}{$var};
                };
            }
        }

        for my $section ( keys %{ $args{multi} } ) {
            my @vars = @{ $args{multi}->{$section} };
            for my $var ( @vars ) {
                *{ "${class}::${section}_${var}" } = sub {
                    my $val = $config->{$section}{$var};
                    return [ $val ] unless 'ARRAY' eq ref $val;
                    return $val;
                }
            }
        }
    }

    return;
}

package main;

use strict; use warnings;

my $config = My::Config->new;

use Data::Dumper;
print Dumper($config->install_root, $config->template_dir);

C:\Temp> cat config.ini
[install]
root = c:\opt

[template]
dir = C:\opt\app\tmpl
dir = C:\opt\common\tmpl

Вывод:

C:\Temp> g.pl
$VAR1 = 'c:\\opt';
$VAR2 = [
          'C:\\opt\\app\\tmpl',
          'C:\\opt\\common\\tmpl'
        ];

Для файлов конфигурации я предпочитаю использовать YAML. Простая, кроссплатформенная, удобочитаемая, и нет опасности того, что ваша конфигурация случайно превратится в настоящую программу.

Библиотека Config:Properties удобна для чтения и записи. файлы свойств пары ключ/значение.

Я предпочитаю YAML и YAML::XS для данных конфигурации. Он простой, читаемый и имеет привязки практически для любого языка программирования. Другой популярный вариант — Config::General.

Обычный низкотехнологичный метод заключается в простом выполнении EXPR файла конфигурации. . Вы изучали это?

Рискуя быть высмеянным из класса, одно из решений состоит в том, чтобы хранить конфигурацию в XML (или, для более авантюрного, в JSON). Доступный человеку, интероперабельный за пределами Perl, не должен жить на локальном ПК (и XML, и JSON могут быть запрошены из «URL-адреса конфигурации») и набора стандартных модулей (XML::Simple обычно достаточно хорош для XML-файлы конфигурации) существуют на CPAN.

Для такой простой конфигурации, особенно для тривиальных вещей, когда я не ожидаю, что эти данные изменятся в реальном мире, я часто просто использую YAML. Простота не может быть превзойдена:

Сначала напишите свою структуру данных Perl, содержащую вашу конфигурацию.

use YAML;

my $SETTINGS = {
    '1' => "foo",
    '2' => ["123", "456"],
    '3' => "something",
};

Затем передайте его в YAML::DumpFile();

YAML::DumpFile("~/.$appname.yaml", $SETTINGS);

Удалите структуру данных и замените ее на

my $SETTINGS = YAML::LoadFile("~/.$appname.yaml");

А потом забудьте об этом. Даже если вы не знаете или не хотите изучать синтаксис YAML, небольшие изменения в конфигурации можно внести вручную, а более серьезные — в Perl, а затем повторно выгрузить в YAML.

Не привязывайтесь к формату — используйте Config::Any или для немного большего фактора DWIM, Config::JFDI (который сам обертывает Config ::Любой). С ними вы покупаете себе возможность поддерживать INI, YAML, XML, конфигурацию в стиле Apache и многое другое.