Почему моя подпрограмма Perl не может увидеть значение переменной в цикле foreach, который ее вызвал?

Вы объявляете $RootDirectory как переменную цикла в foreach цикле. Насколько я понимаю, это означает, что его значение local привязано к циклу, а его значение восстанавливается до своего предыдущего значения в конце цикла.

В вашем случае переменная никогда не была назначена, поэтому в конце цикла она возвращается к своему предыдущему значению undef.

Изменить: на самом деле проблема в том, что $RootDirectory объявлен с my, поэтому он не определен в других областях. В функциях RunSchema, CreateTables и SQLExecFolder переменная не определена, независимо от локализации foreach.

Если вы хотите, чтобы переменная была объявлена ​​для strictness, но чтобы она была глобальной, объявите $RootDirectory с our:

our $RootDirectory;

Изменить: при этом не всегда рекомендуется использовать глобальную переменную. Вам лучше передать переменную в качестве параметра функциям, как предлагали другие.

То, что сказал Натан, правильно. Помимо этого, почему бы вам не передать значение? В любом случае это лучше практика:

foreach $RootDirectory (@RootDirectories) { 
   # $RootDirectory = 'c:\\P4\\EDW\\PRODEDW\\EDWDM\\main\\db\\';
   # print ' In foreach ' . $RootDirectory. "\n";
   RunSchema ($RootDirectory);
} 

sub SQLExecFolder { 
   my $RootDirectory = shift;
   print ' In SQLExecFolder ' . $RootDirectory. "\n";
} 

Остальные правильно ответили на ваш вопрос. Я просто хочу подчеркнуть, что вы должны добавить use warnings; в свой код. Это дало бы ключ к разгадке вашей проблемы и предупредило бы вас о другой потенциальной опасности.

foreach переменная особенная - она ​​локальная для цикла.

Если перед переменной стоит ключевое слово my, то она имеет лексическую область видимости и поэтому видна только внутри цикла. В противном случае переменная неявно является локальной для цикла и восстанавливает свое прежнее значение при выходе из цикла. Если переменная была ранее объявлена ​​с помощью my, она использует эту переменную вместо глобальной, но по-прежнему локализована для цикла. Эта неявная локализация происходит только в цикле foreach.

Загляните сюда

Переменная итератора в цикле foreach всегда локализована в цикле. См. Раздел foreach в perlsyn. Вы можете передать его подпрограмме в качестве параметра.

RE: Когда использовать глобальную переменную?

Глобальные переменные опасны, потому что они могут быть изменены в любое время любой частью кода, которая обращается к ним. Кроме того, трудно отследить, когда и где происходит изменение, что затрудняет отслеживание непреднамеренных последствий модификации. Короче говоря, каждая глобальная переменная увеличивает связь между подпрограммами, которые ее используют.

Когда имеет смысл использовать глобал? Когда преимущества перевешивают риски.

Если у вас есть много разных значений, необходимых для большинства или всех ваших подпрограмм, похоже, подходящее время для использования глобальных переменных. Вы можете упростить каждый вызов подпрограммы и сделать код более понятным, верно?

НЕПРАВИЛЬНЫЙ. В этом случае правильный подход - объединить все эти различные переменные в одну структуру данных контейнера. Итак, вместо foo( $frob, $grizzle, $cheese, $omg, $wtf ); у вас есть foo( $state, $frob ); Где $state = { grizzle => $grizzle, cheese => $cheese, omg => $omg, wtf => $wtf };.

Итак, теперь у нас есть одна переменная, которую нужно передать. Все эти дополнительные вызовы намного проще. Тем не менее, даже в этом случае это обременительно, и вы все равно хотите убрать лишний аргумент из каждой процедуры.

На данный момент у вас есть несколько вариантов:

1. Сделайте $state глобальным и просто обращайтесь к нему напрямую.
2. Превратите $state в объект конфигурации и используйте методы для управления доступом к атрибутам.
3. Превратите весь модуль в класс и сохраните всю информацию о состоянии в объекте.

Вариант 1 приемлем для небольших скриптов с небольшим количеством подпрограмм. Риск трудно поддающихся отладке ошибок невелик.

Вариант 2 имеет смысл, когда нет очевидной взаимосвязи между различными подпрограммами в модуле. Использование объекта глобального состояния помогает, поскольку уменьшает связь между кодом, который обращается к нему. Также проще добавить ведение журнала для отслеживания изменений глобальных данных.

Вариант 3 хорошо работает, если у вас есть группа тесно связанных функций, которые работают с одними и теми же данными.

Ваш пример кода кажется хорошим кандидатом для варианта 3. Я создал класс с именем MySchema, и все методы, которые работают с определенным каталогом, теперь являются методами. Вызывающий объект несет с собой необходимые данные.

Теперь у нас есть красивый, чистый код и никаких глобальных переменных.

use strict;
use warnings;

my @directories = (
   'c:\\P4\\EDW\\PRODEDW\\EDWDM\\main\\db\\',
   'c:\\P4\\EDW\\PRODEDW\\EDWADS\\main\\db\\',
   'c:\\P4\\EDW\\PRODEDW\\FJE\\main\\db\\',
);

for my $schema ( make_schemata(@directories) ) {

    $schema->run;

}

sub make_schemata {
    my @schemata = map { MySchema->new( directory => $_ } @_;

    return @schemata;
}


BEGIN {
    package MySchema;

    use Moose;

    has 'directory' => (
        is => 'ro',
        isa => 'Str',
        required => 1,
    );

    sub run { 
       my $self = shift;

       $self->create_tables;
    } 

    sub create_tables { 
       my $self = shift;

       $self->sql_exec_folder('tbl');
    }

    sub sql_exec_folder {
        my $self = shift;

        my $dir = $self->directory;

        print "In SQLExecFolder $dir\n";
    }
    
    1;
} 

В качестве бонуса код в блоке BEGIN можно удалить и поместить в отдельный файл для повторного использования другим скриптом. Все, что ему нужно, чтобы быть полноценным модулем, - это собственный файл с именем MySchema.pm.

Неплохое усилие. Вот пара небольших улучшений и одно «исправление», которое заключается в передаче переменной в подпрограммы в качестве параметра функции, поскольку переменная $RootDirectory ограничена (т.е. ограничена) в пределах цикла foreach. В целом также считается хорошей практикой указывать, какие переменные передаются и / или к которым осуществляется доступ для различных подпрограмм.

use strict;
use warnings;

sub RunSchema() {
   my $root_dir = shift;
   CreateTables($root_dir);
}

sub CreateTables() {
   my $root_dir = shift;
   SQLExecFolder('tbl', $root_dir);
}

sub SQLExecFolder() {
   my ($name, $root_dir) = @_;
}
######################################################


my @RootDirectories = qw(
   c:\\P4\\EDW\\PRODEDW\\EDWDM\\main\\db\\
   c:\\P4\\EDW\\PRODEDW\\EDWADS\\main\\db\\
   c:\\P4\\EDW\\PRODEDW\\FJE\\main\\db\\
);

foreach my $RootDirectory (@RootDirectories) {
   # print ' In foreach ' . $RootDirectory. "\n";
   RunSchema($RootDirectory);
}

exit(0);