Как предотвратить дублирование в XSL?

Как предотвратить дублирование записей в списке, а затем, в идеале, отсортировать этот список? Что я делаю, так это когда информация на одном уровне отсутствует, беру информацию с уровня ниже этого, чтобы построить недостающий список на уровне выше. В настоящее время у меня есть XML, подобный этому:

<c03 id="ref6488" level="file">
    <did>
        <unittitle>Clinic Building</unittitle>
        <unitdate era="ce" calendar="gregorian">1947</unitdate>
    </did>
    <c04 id="ref34582" level="file">
        <did>
            <container label="Box" type="Box">156</container>
            <container label="Folder" type="Folder">3</container>
        </did>
    </c04>
    <c04 id="ref6540" level="file">
        <did>
            <container label="Box" type="Box">156</container>
            <unittitle>Contact prints</unittitle>
        </did>
    </c04>
    <c04 id="ref6606" level="file">
        <did>
            <container label="Box" type="Box">154</container>
            <unittitle>Negatives</unittitle>
        </did>
    </c04>
</c03>

Затем я применяю следующий XSL:

<xsl:template match="c03/did">
    <xsl:choose>
        <xsl:when test="not(container)">
            <did>
                <!-- If no c03 container item is found, look in the c04 level for one -->
                <xsl:if test="../c04/did/container">

                    <!-- If a c04 container item is found, use the info to build a c03 version -->
                    <!-- Skip c03 container item, if still no c04 items found -->
                    <container label="Box" type="Box">

                        <!-- Build container list -->
                        <!-- Test for more than one item, and if so, list them, -->
                        <!-- separated by commas and a space -->
                        <xsl:for-each select="../c04/did">
                            <xsl:if test="position() &gt; 1">, </xsl:if>
                            <xsl:value-of select="container"/>
                        </xsl:for-each>
                    </container>                    
            </did>
        </xsl:when>

        <!-- If there is a c03 container item(s), list it normally -->
        <xsl:otherwise>
            <xsl:copy-of select="."/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Но я получаю результат "контейнера"

<container label="Box" type="Box">156, 156, 154</container>

когда я хочу

<container label="Box" type="Box">154, 156</container>

Ниже приведен полный результат, который я пытаюсь получить:

<c03 id="ref6488" level="file">
    <did>
        <container label="Box" type="Box">154, 156</container>
        <unittitle>Clinic Building</unittitle>
        <unitdate era="ce" calendar="gregorian">1947</unitdate>
    </did>
    <c04 id="ref34582" level="file">
        <did>
            <container label="Box" type="Box">156</container>
            <container label="Folder" type="Folder">3</container>
        </did>
    </c04>
    <c04 id="ref6540" level="file">
        <did>
            <container label="Box" type="Box">156</container>
            <unittitle>Contact prints</unittitle>
        </did>
    </c04>
    <c04 id="ref6606" level="file">
        <did>
            <container label="Box" type="Box">154</container>
            <unittitle>Negatives</unittitle>
        </did>
    </c04>
</c03>

Заранее благодарю за любую помощь!


duplicates xslt
person LOlliffe    schedule 19.04.2010    source источник
comment
Хороший вопрос (+1). См. мой ответ для решения XSLT 1.0, которое короче выбранного в настоящее время решения XSLT 2.0. :)   -  person Dimitre Novatchev    schedule 20.04.2010

Ответы (6)


arrow_upward
2
arrow_downward

Попробуйте следующий код:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output indent="yes"></xsl:output>

<xsl:template match="node() | @*">
  <xsl:copy>
    <xsl:apply-templates select="node() | @*"/>
  </xsl:copy>
</xsl:template>

  <xsl:template match="c03/did">
    <xsl:choose>
      <xsl:when test="not(container)">
        <did>
          <!-- If no c03 container item is found, look in the c04 level for one -->
          <xsl:if test="../c04/did/container">
            <xsl:variable name="foo" select="../c04/did/container[@type='Box']/text()"/>
            <!-- If a c04 container item is found, use the info to build a c03 version -->
            <!-- Skip c03 container item, if still no c04 items found -->
            <container label="Box" type="Box">

              <!-- Build container list -->
              <!-- Test for more than one item, and if so, list them, -->
              <!-- separated by commas and a space -->
              <xsl:for-each select="distinct-values($foo)">
                <xsl:sort />
                <xsl:if test="position() &gt; 1">, </xsl:if>
                <xsl:value-of select="." />
              </xsl:for-each>
            </container>
            <xsl:apply-templates select="*" />
          </xsl:if>
        </did>
      </xsl:when>

      <!-- If there is a c03 container item(s), list it normally -->
      <xsl:otherwise>
        <xsl:copy-of select="."/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

Это выглядит примерно так, как вы хотите:

<?xml version="1.0" encoding="UTF-8"?>
<c03 id="ref6488" level="file">
  <did>
      <container label="Box" type="Box">154, 156</container>
      <unittitle>Clinic Building</unittitle>
      <unitdate era="ce" calendar="gregorian">1947</unitdate>
   </did>
  <c04 id="ref34582" level="file">
      <did>
         <container label="Box" type="Box">156</container>
         <container label="Folder" type="Folder">3</container>
      </did>
  </c04>
  <c04 id="ref6540" level="file">
      <did>
         <container label="Box" type="Box">156</container>
         <unittitle>Contact prints</unittitle>
      </did>
  </c04>
  <c04 id="ref6606" level="file">
      <did>
         <container label="Box" type="Box">154</container>
         <unittitle>Negatives</unittitle>
      </did>
  </c04>
</c03>

Хитрость заключается в том, чтобы использовать <xsl:sort> и distinct-values() вместе. См. (ИМХО) замечательную книгу Майкла Ки "XSLT 2.0 и XPATH 2.0"

person topskip    schedule 19.04.2010
comment
Я использую XSLT2, поэтому я выбрал это решение, и оно отлично сработало. Единственное, мне пришлось закомментировать \‹xsl:apply-templates select=* \/\› По какой-то причине это дублировало узлы unittitle. Большое спасибо! - person LOlliffe; 20.04.2010
comment
Я разделяю ваше высокое мнение о книге Майкла Кея. К сожалению, слишком мало людей/организаций перешли на XSLT 2.0. - person Dimitre Novatchev; 01.05.2010

arrow_upward
3
arrow_downward

Для этой проблемы нет необходимости в решении XSLT 2.0.

Вот решение XSLT 1.0, которое более компактно, чем выбранное в настоящее время решение XSLT 2.0 (35 строк против 43 строк):

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:key name="kBoxContainerByVal"
     match="container[@type='Box']" use="."/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="c03/did[not(container)]">
   <xsl:copy>

   <xsl:variable name="vContDistinctValues" select=
    "/*/*/*/container[@type='Box']
            [generate-id()
            =
             generate-id(key('kBoxContainerByVal', .)[1])
            ]
            "/>

    <container label="Box" type="Box">
      <xsl:for-each select="$vContDistinctValues">
        <xsl:sort data-type="number"/>

        <xsl:value-of select=
        "concat(., substring(', ', 1 + 2*(position() = last())))"/>
      </xsl:for-each>
    </container>
    <xsl:apply-templates/>
   </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к первоначально предоставленному XML-документу, создается правильный желаемый результат:

<c03 id="ref6488" level="file">
   <did>
      <container label="Box" type="Box">156, 154</container>
      <unittitle>Clinic Building</unittitle>
      <unitdate era="ce" calendar="gregorian">1947</unitdate>
   </did>
   <c04 id="ref34582" level="file">
      <did>
         <container label="Box" type="Box">156</container>
         <container label="Folder" type="Folder">3</container>
      </did>
   </c04>
   <c04 id="ref6540" level="file">
      <did>
         <container label="Box" type="Box">156</container>
         <unittitle>Contact prints</unittitle>
      </did>
   </c04>
   <c04 id="ref6606" level="file">
      <did>
         <container label="Box" type="Box">154</container>
         <unittitle>Negatives</unittitle>
      </did>
   </c04>
</c03>

Обновление:

Я не заметил требования, чтобы номера контейнеров отображались отсортированными. Теперь решение отражает это.

person Dimitre Novatchev    schedule 20.04.2010
comment
Ваше решение не сортирует список, который был запрошен в вопросе. Это легко исправить, добавив <xsl:sort/> внутрь цикла xsl:for-each. - person markusk; 20.04.2010
comment
@markusk: Спасибо, я обычно сонный рано утром. <xsl:sort/> в этом случае также требуется data-type="number". - person Dimitre Novatchev; 20.04.2010

arrow_upward
1
arrow_downward

попробуйте использовать группу Key в xslt, вот статья о методе Muenchian, который должен помочь устранить дубликаты. http://www.jenitennison.com/xslt/grouping/muenchian.html

person derek    schedule 19.04.2010
comment
Статья Джени очень хорошо объясняет менчский метод для слабоумных (таких как я)! - person Chris Fewtrell; 10.06.2010

arrow_upward
1
arrow_downward

Немного более короткая версия XSLT 2.0, сочетающая подходы из других ответов. Обратите внимание, что сортировка выполняется в алфавитном порядке, поэтому, если будут найдены метки «54» и «156», вывод будет «156, 54». Если требуется числовая сортировка, используйте <xsl:sort select="number(.)"/> вместо <xsl:sort/>.

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/>

    <xsl:template match="node()|@*"> 
        <xsl:copy> 
            <xsl:apply-templates select="node()|@*"/> 
        </xsl:copy> 
    </xsl:template> 

    <xsl:template match="c03/did[not(container)]">
        <xsl:variable name="containers" 
                      select="../c04/did/container[@label='Box'][text()]"/>
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:if test="$containers">
                <container label="Box" type="Box">
                    <xsl:for-each select="distinct-values($containers)">
                        <xsl:sort/>
                        <xsl:if test="position() != 1">, </xsl:if>
                        <xsl:value-of select="."/>
                    </xsl:for-each>
                </container> 
            </xsl:if>
            <xsl:apply-templates select="node()"/> 
        </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet>
person markusk    schedule 20.04.2010

arrow_upward
1
arrow_downward

Настоящее решение XSLT 2.0, к тому же довольно короткое:

<xsl:stylesheet  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs"
>
  <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="c03/did[not(container)]">
    <xsl:copy>
      <xsl:copy-of select="@*"/>

      <xsl:variable name="vContDistinctValues" as="xs:integer*">
        <xsl:perform-sort select=
          "distinct-values(/*/*/*/container[@type='Box']/text()/xs:integer(.))">
          <xsl:sort/>
        </xsl:perform-sort>
      </xsl:variable>

      <xsl:if test="$vContDistinctValues">
        <container label="Box" type="Box">
          <xsl:value-of select="$vContDistinctValues" separator=","/>
        </container>
      </xsl:if>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

Обратите внимание:

  1. Использование типов позволяет избежать необходимости указывать data-type в <xsl:sort/> .

  2. Использование атрибута separator для <xsl:value-of/>

person Dimitre Novatchev    schedule 20.04.2010
comment
+1 Красиво сделано. Однако знаем ли мы, что элемент c03 будет корнем? Автор только заявил, что входные данные будут похожими, поэтому я чувствую себя более комфортно с относительными XPath (т. е. ../c04/container или, возможно, ../*/container) вместо абсолютных (/*/*/*/container). Таким образом, таблица стилей работает, даже если элемент c03 появляется ниже в структуре документа. - person markusk; 20.04.2010
comment
@markusk Еще раз хороший комментарий, и спасибо за голосование! Да, мы наблюдаем, как ОП постоянно меняют определение своих проблем. Иногда у меня возникает соблазн выступить в роли гадалки, но это тоже сопряжено с риском. Кроме того, код XSLT становится все более и более не слишком напрямую связанным с фактическим XML и, следовательно, более трудным для понимания. Вот почему в подобных случаях я обычно предпочитаю оставаться как можно ближе к опубликованному XML. Я много раз писал наиболее общий код XSLT, например. XPath Visualizer/FXSL, но цель здесь состоит в том, чтобы быть как можно более конкретным/полезным. :) - person Dimitre Novatchev; 20.04.2010

arrow_upward
0
arrow_downward

Следующее преобразование XSLT 1.0 делает то, что вы ищете.

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
> 
  <xsl:output encoding="utf-8" />

  <!-- key to index containers by these three distinct qualities: 
       1: their ancestor <c??> node (represented as its unique ID)
       2: their @type attribute value
       3: their node value (i.e. their text) -->
  <xsl:key 
    name  = "kContainer" 
    match = "container"
    use   = "concat(generate-id(../../..), '|', @type, '|', .)"
  />

  <!-- identity template to copy everything as is by default -->
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*" />
    </xsl:copy>
  </xsl:template>

  <!-- special template for <did>s without a <container> child -->
  <xsl:template match="did[not(container)]">
    <xsl:copy>
      <xsl:copy-of select="@*" />
      <container label="Box" type="Box">
        <!-- from subordinate <container>s of type Box, use the ones
             that are *the first* to have that certain combination 
             of the three distinct qualities mentioned above -->
        <xsl:apply-templates mode="list-values" select="
          ../*/did/container[@type='Box'][
            generate-id()
            =
            generate-id(
              key(
                'kContainer', 
                concat(generate-id(../../..), '|', @type, '|', .)
              )[1]
            )
          ]
        ">
          <!-- sort them by their node value -->
          <xsl:sort select="." data-type="number" />
        </xsl:apply-templates>
      </container>
      <xsl:apply-templates select="node()" />
    </xsl:copy>
  </xsl:template>

  <!-- generic template to make list of values from any node-set -->
  <xsl:template match="*" mode="list-values">
    <xsl:value-of select="." />
    <xsl:if test="position() &lt; last()">
      <xsl:text>, </xsl:text>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

Возвращает

<c03 id="ref6488" level="file">
  <did>
    <container label="Box" type="Box">154, 156</container>
    <unittitle>Clinic Building</unittitle>
    <unitdate era="ce" calendar="gregorian">1947</unitdate>
  </did>
  <c04 id="ref34582" level="file">
    <did>
      <container label="Box" type="Box">156</container>
      <container label="Folder" type="Folder">3</container>
    </did>
  </c04>
  <c04 id="ref6540" level="file">
    <did>
      <container label="Box" type="Box">156</container>
      <unittitle>Contact prints</unittitle>
    </did>
  </c04>
  <c04 id="ref6606" level="file">
    <did>
      <container label="Box" type="Box">154</container>
      <unittitle>Negatives</unittitle>
    </did>
  </c04>
</c03>

Часть generate-id() = generate-id(key(...)[1]) — это так называемая мюнхенская группировка. Если вы не можете использовать XSLT 2.0, это путь.

person Tomalak    schedule 19.04.2010