Максимальный размер/смещение потокового файла с использованием Ada.Streams.Stream_IO.Read

В Mac OS X с FSF GCC 5.1.0 есть

procedure Read
  (File : File_Type;
   Item : out Stream_Element_Array;
   Last : out Stream_Element_Offset;
   From : Positive_Count);

куда

type Count is new Stream_Element_Offset
  range 0 .. Stream_Element_Offset’Last;

subtype Positive_Count is Count range 1 .. Count’Last;            --'
--  Index into file, in stream elements

и (в Ada.Streams)

type Stream_Element_Offset is new Long_Long_Integer;

то есть 64 бита .. должно хватить.

Однако, как отмечает Алекс, GNAT GPL 2014

type Stream_Element_Offset is range
  -(2 ** (Standard'Address_Size - 1)) ..
  +(2 ** (Standard'Address_Size - 1)) - 1;

это означает, что на 32-битной машине вы ограничены файлами размером 2 гигабайта.

Последние исходники FSF GCC (как для 5.1.0 выше) были изменены; нам придется подождать до GNAT GPL 2015, чтобы увидеть, что является окончательным.

Еще одной причиной для беспокойства является код GNAT GPL 2014 для Ada.Streams.Stream_IO.Set_Position (внутренняя подпрограмма).

procedure Set_Position (File : File_Type) is
   use type System.CRTL.long;
   use type System.CRTL.ssize_t;
   R : int;
begin
   if Standard'Address_Size = 64 then
      R := fseek64 (File.Stream,
                    System.CRTL.ssize_t (File.Index) - 1, SEEK_SET);
   else
      R := fseek (File.Stream,
                  System.CRTL.long (File.Index) - 1, SEEK_SET);
   end if;

   if R /= 0 then
      raise Use_Error;
   end if;
end Set_Position;

тогда как версия GCC 5.1.0 (у которой нет альтернативных реализаций)

procedure Set_Position (File : File_Type) is
   use type System.CRTL.int64;
   R : int;
begin
   R := fseek64 (File.Stream, System.CRTL.int64 (File.Index) - 1, SEEK_SET);

   if R /= 0 then
      raise Use_Error;
   end if;
end Set_Position;

Если в вашей системе есть fseek64() - или, возможно, fseeko(), что принимает off_t, а не long для параметра offset - и друзья (я думаю, что так и должно быть, глядя на код выше), я думаю, что было бы не слишком сложно написать свой собственную версию Ada.Streams.Stream_IO, чтобы всегда использовать 64-битные функции. Вероятно, проще всего назвать его My_Stream_IO и стиснуть зубы о предупреждениях компилятора об использовании внутренних модулей GNAT, а не пытаться вставить его в иерархию Ada.

Если вы хотите узнать диапазон скалярного типа, вы можете получить доступ к минимальному и максимальному значениям, используя <type>'First и <type>'Last:

with Ada.Text_IO;

procedure Check_Range is
   use Ada.Text_IO;
   subtype Type_To_Check is Integer;
begin
   Put (Type_To_Check'Image (Type_To_Check'First));
   Put (" .. ");
   Put (Type_To_Check'Image (Type_To_Check'Last));
   New_Line;
end Check_Range;

Если вы хотите получить доступ к файлам большего размера, чем поддерживает стандартная библиотека, вы можете импортировать функции операционной системы, дающие доступ к самым большим файлам, разрешенным вашей операционной системой.

Подробная информация об импорте функций из других языков указана в приложении B в справочнике по языку.