Вызов процедуры в цикле с нестатическим именем сигнала

Интересно, что если foo является локальной переменной процесса (и s настроена соответствующим образом), ghdl компилирует это. Что подчеркивает проблему в исходной версии. Цикл «for» требуется для управления всем foo все время, потому что вы не можете заставить сигнальные драйверы появляться или исчезать по желанию — он не может быть амбивалентным в отношении того, какие биты он управляет (и, как вы можете видеть, процедура пытается управлять разными битами в разное время).

Поэтому, если вы можете перенастроить свое приложение, чтобы разрешить семантику обновления переменных, и сделать foo переменной локальной для процесса, это сработает. (Вам придется копировать его значение в сигнал перед каждым «ожиданием», если вы хотите увидеть эффект!)

В качестве альтернативы передайте весь сигнал foo и индекс подпрограмме, чтобы последняя всегда управляла всеми foo следующим образом... (Я также добавил недостающие биты и исправил ложное параллельное «ожидание»: в будущем ПОЖАЛУЙСТА проверьте, действительно ли ваш пример кода компилируется перед публикацией!)

library ieee;
use ieee.std_logic_1164.all;

entity test is
end test;

architecture tb of test is
    signal foo : std_logic_vector(1 downto 0);
begin
    dummy: process is
        procedure do_something (
            signal s : out std_logic_vector(1 downto 0); 
            constant i : in natural
        ) is begin
            s <= (others => '0');
            s(i) <= '1';
            report "tic";
            wait for 1 ns;
            -- actually we would do something more interesting here
            s(i) <= '0';
            report "toc";
        end procedure;

    begin
        -- This works well, but requires manual loop-unrolling
        do_something(foo,0);
        do_something(foo,1);

        -- This should do the same 
        for i in foo'range loop
            -- This is the offending line:
            do_something(foo,i);
        end loop;
        wait; -- for ever
    end process dummy;

end architecture tb;

Я разделяю ваши чувства по поводу того, что это глупое ограничение языка. За вычетом операторов wait и report ваш пример, безусловно, имеет действительную аппаратную реализацию, не говоря уже о четко определенном поведении моделирования.

Я думаю, что в большинстве случаев этой ситуации можно избежать. Например, в вашем простом примере вы можете просто скопировать содержимое процедуры в тело процесса или передать весь вектор, как предложил Брайан. Если вам действительно нужно это сделать, это один из обходных путей:

architecture tb of test is
    signal foo : std_logic_vector(1 downto 0);
    signal t : std_logic;
    signal p : integer := 0;
begin
    foo(p) <= t;

    dummy: process is
        procedure do_something (
            signal s : out std_logic
        ) is begin
            s <= '1';
            wait for 1 ns;
            s <= '0';
        end procedure;
    begin
        for i in foo'range loop
            p <= idx;
            do_something(t);
            wait for 0 ns;
        end loop;
        wait;
    end process dummy;
end architecture tb;

Это работает только в моделировании и приведет к задержке одного дельта-цикла на итерацию по сравнению с развертыванием цикла, который завершается за нулевое время, когда процедура не содержит операторов ожидания.