Не могу понять функцию printf в сборке x86 и работу с операндами

Везде, где я находил проблему, я добавлял *** в комментариях. Несколько замечаний:

• У вас были опечатки в некоторых ярлыках.
• NASM чувствителен к регистру, поэтому mulfun — это не то же самое, что mulFun.
• Если у вас есть инструкция, принимающая один или несколько операндов, которая не использует регистр (для источника или адресата), но ссылается на память, вам необходимо указать размер операнда памяти. Например, cmp [op], '+' размер данных, на которые ссылается [op], должен быть указан, поэтому вы добавляете к нему префикс размера. Размер может быть byte, word, dword. Вы сравниваете один символ, поэтому размер будет byte . Код должен был выглядеть так cmp byte [op], '+'
• Если у вас есть переменная, и вы делаете mov eax, varname, это перемещает адрес varname в EAX. Если вы хотите переместить содержимое varname, вы должны заключить его в квадратные скобки, например mov eax, [varname] . При работе со строковыми адресами и подпрограмме print_string вам нужно передать адрес строки в EAX, а не ее содержимое. Так что опусти скобки.
• Если вы используете call для вызова функции, ваша функция должна заканчиваться на ret.
• Не jmp к функции, используйте call
• Если вы хотите напечатать символ, не используйте print_string, используйте print_char. Поместите персонажа в EAX
• Если вы хотите напечатать целое число, не используйте print_string, используйте print_int. Поместите целое число в EAX

Пересмотренный код выглядит следующим образом:

;program to add, multiply, or give the power of a number

%include "asm_io.inc"

segment .data

prompt1 db    "Enter a number: ", 0        ;prompts
prompt2 db    "Enter another number: ", 0
prompt3 db    "Enter an operand", 0
prompt4 db    "OP ", 0    ;idiotic prompts for printing
prompt5 db    " = ", 0    ;another printing prompt

segment .bss

num1  resd 1    ;variable for 1st number
num2  resd 1    ;variable for 2nd number
op    resd 1    ;variable for operand


segment .text

    global  asm_main
asm_main:
    enter   0,0                 ; setup routine
    pusha

    restart:
        mov     eax, prompt1    ; print out prompt
        call    print_string
        call    print_nl

        call    read_int        ; read integer
        mov     [num1], eax     ; store into num1
        call    print_nl

        mov     eax, prompt2    ; print out prompt
        call    print_string
        call    print_nl

        call    read_int        ; read integer
        mov     [num2], eax     ; store into num2
        call    print_nl

        mov     eax, prompt3    ;print out prompt
                                ;*** Typo - promtp3 changed to prompt3
        call    print_string
        call    print_nl

        call    read_char       ;read operand and dispose of null
        call    read_char
        mov     [op], eax       ;store operand in [op]
        call    print_nl

        cmp     byte [op], '*'  ;operand comparison
                                ;*** We must specify the size of data we are
                                ;*** comparing, so we tell the assembler that
                                ;*** with 'byte' in front of the variable
        jne     jmp1
        call    mulFun
        jmp     restart

jmp1:   cmp     byte [op], '+'  ;operand comparison
                                ;*** We must specify the size of data we are
                                ;*** comparing, so we tell the assembler that
                                ;*** with 'byte' in front of the variable
        jne     jmp2
        call    sumFun
        jmp     restart

jmp2:   cmp     byte [op], '^'  ;operand comparison
                                ;*** We must specify the size of data we are
                                ;*** comparing, so we tell the assembler that
                                ;*** with 'byte' in front of the variable
        jne     jmp3
;        call    expFun         ;*** This expFun function doesn't exist so
                                ;*** don't call it so we can compile and link
        jmp     restart

jmp3:   cmp     byte [op], 'e'  ;exit function
                                ;*** We must specify the size of data we are
                                ;*** comparing, so we tell the assembler that
                                ;*** with 'byte' in front of the variable
        je      end1

end1:
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    call    print_nl          ; pr
    popa
    mov     eax, 0            ; return back to C
    leave
    ret
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
mulFun:                     ;multiplication function
                            ;*** NASM is case sensitive - changed mulfun to mulFun
    mov     ebx, [num1]
    mov     ecx, [num2]
    imul    ebx, ecx
    call    printFun        ;*** Call printFun, don't 'jmp' to it
    ret                     ;*** Since mulfun was called, we use 'ret' to return

sumFun:                     ;sum function
    mov     ebx, [num1]
    mov     ecx, [num2]
    add     ebx, ecx
    call    printFun
    ret

printFun:                   ;printing function
    mov     eax, prompt4    ;*** We want the address of prompt4, not what is at prompt4
                            ;*** Remove the brackets from [prompt4]
    call    print_string
    mov     eax, [num1]
    call    print_int       ;*** Use print_int to print an integer, not print_string
    mov     eax, [op]
    call    print_char      ;*** Use print_char to print a char, not print_string
    mov     eax, [num2]
    call    print_int       ;*** Use print_int to print an integer, not print_string
    mov     eax, prompt5    ;*** We want the address of prompt5, not what is at prompt5
                            ;*** Remove the brackets from [prompt5]
    call    print_string
    mov     eax, ebx
    call    print_int       ;*** Use print_int to print an integer, not print_string;
    call    print_nl
    ret

Я оставлю разработку функции expFun на усмотрение авторов оригинального постера. На данный момент я закомментировал его, чтобы существующий код можно было собрать, скомпоновать и запустить.

Вы можете использовать printf, но я думаю, что долгий путь тоже может научить кое-чему, и я исключил обсуждение printf из своего ответа. Ваш инструктор, учебные материалы, помощник преподавателя могут стать хорошей отправной точкой для других ваших вопросов.

Этот ответ предоставляется, чтобы привести вашу программу в пригодное для использования состояние, чтобы вы могли продолжить выполнение задания. На мой взгляд, исходный вопрос слишком широк. Если требуется дополнительная помощь, вероятно, лучше всего задать новый вопрос по конкретной проблеме.