Ошибка чтения диска при загрузке секторов в память

"Он составляет список, он проверяет его дважды..."

• Ваш загрузчик запускается в режиме реального адреса, поэтому лучше всего заставить ваш ассемблер использовать 16-битный код. Вы достигаете этого в NASM, написав [bits 16] в верхней части вашей программы.

• Когда ваш загрузчик запустится, BIOS поместит его по линейному адресу 00007C00h. Это можно сделать несколькими способами в отношении комбинации сегмента и смещения.
  Когда вы явно написали [org 0x7C00], вы (отчасти) ожидали, что эта комбинация будет иметь часть сегмента, равную нулю. Но это ни в коем случае не обязанность BIOS! Таким образом, вы должны установить сегментные регистры (DS, ES и SS) вручную.

• Функция телетайпа BIOS, которую вы используете в подпрограмме print_string, использует BL и BH в качестве параметров. Таким образом, вы никогда не должны использовать регистр BX для адресации вашего текста. Конечно, некоторые BIOS не используют эти параметры BL и BH (больше), но стараются разрабатывать программы для самой широкой аудитории.

• Когда вы инициализируете регистр SP значением 0x9000, вы фактически создаете стек, который может легко, незаметно для вас перезаписать программу под ним! Лучше всего будет выбрать комбинацию SS и SP, которая удовлетворяет ваши потребности и не более того. Для стека размером 4608 байт, который находится над загрузочным сектором на 7C00h и заканчивается на 9000h, потребуется: SS=07E0h SP=1200h. Чтобы избежать каких-либо проблем с оборудованием 8086, лучше отключить прерывания при изменении SS:SP.

• Вы использовали инструкции pusha и popa. Это недействительные инструкции для оборудования 8086. При написании надежного программного обеспечения мы должны проверить, соответствует ли аппаратное обеспечение поставленной задаче. Но здесь самое простое решение — использовать только одиночные регистры.

• Вы интерпретировали значение, возвращаемое функцией BIOS, которая считывает данные с диска, но вы просто прерываете операцию, когда было передано неправильное количество секторов. Это неправильный подход. Когда BIOS сообщает вам о незавершенной передаче (это может произойти, если ваш BIOS не поддерживает многодорожечность), вы должны повторить вызов для оставшегося количества секторов. Очевидно, что некоторые параметры должны быть скорректированы: следующая головка, может быть, следующий цилиндр, и всегда сектор = 1. (Идеальным решением было бы получение геометрии диска из BIOS или чтение ее из BPB, присутствующего на диске). Я предположил базовую работу с дискетой 1,44 МБ.

• Если чтение с диска не удается с первого раза, следует повторить попытку несколько раз. Такие первые неудачи совершенно нормальны. Пять попыток — это хорошее значение. В промежутках между попытками вы вызываете функцию BIOS, которая сбрасывает дисковод.

• Чтобы убедиться, что QEMU действительно может прочитать эти дополнительные 15 секторов, вы должны дополнить этот файл, чтобы его общая длина равнялась 16 секторам. текст, на который вы ссылаетесь сделать это также!

«Собираем все вместе»

[bits 16]
[org 0x7C00]

KERNEL_OFFSET equ 0x1000

xor  ax, ax
mov  ds, ax
mov  es, ax    
mov  [BOOT_DRIVE], dl
mov  ax, 0x07E0
cli
mov  ss, ax 
mov  sp, 0x1200
sti
mov  si, MSG_REAL_MODE       
call print_string           
call load_kernel            
jmp  $

print_string:
  push ax
  push bx
  push si
  mov  bx, 0x0007  ;BL=WhiteOnBlack BH=Display page 0
  mov  ah, 0x0E    ;Teletype function
 loop:
  mov  al, [si]
  cmp  al, 0
  je return
  int  0x10
  inc  si
  jmp  loop
 return:
  pop  si
  pop  bx
  pop  ax
  ret

disk_load:
  mov  [SECTORS], dh
  mov  ch, 0x00      ;C=0
  mov  dh, 0x00      ;H=0
  mov  cl, 0x02      ;S=2
 next_group:
  mov  di, 5         ;Max 5 tries
 again: 
  mov  ah, 0x02      ;Read sectors
  mov  al, [SECTORS]
  int  0x13
  jc   maybe_retry
  sub  [SECTORS], al ;Remaining sectors
  jz  ready
  mov  cl, 0x01      ;Always sector 1
  xor  dh, 1         ;Next head on diskette!
  jnz  next_group
  inc  ch            ;Next cylinder
  jmp  next_group
 maybe_retry:
  mov  ah, 0x00      ;Reset diskdrive
  int  0x13
  dec  di
  jnz  again
  jmp  disk_error
 ready:
  ret

disk_error:
  mov  si, DISK_ERROR_MSG 
  call print_string 
  jmp  $

DISK_ERROR_MSG db "Disk read error!", 0

load_kernel: 
  mov  bx, KERNEL_OFFSET       
  mov  dh, 15           
  mov  dl, [BOOT_DRIVE]                      
  call disk_load                                                  
  ret

; Global variables
BOOT_DRIVE     db 0
SECTORS        db 0
MSG_REAL_MODE  db "Started in 16-bit Real Mode", 0 

; Bootsector padding 
times 510-($-$$) db 0 
dw 0xAA55

; 15 sector padding
times 15*256 dw 0xDADA