Получите имя пользователя для входа в Jenkins из плагина Jenkins Workflow (Pipeline)

Вы пытались установить плагин Build User Vars? Если это так, вы сможете запустить

node {
  wrap([$class: 'BuildUser']) {
    def user = env.BUILD_USER_ID
  }
}

или похожие.

Чтобы он работал с Jenkins Pipeline:

Установите подключаемый модуль переменных сборки пользователя

Затем запустите следующее:

pipeline {
  agent any

  stages {
    stage('build user') {
      steps {
        wrap([$class: 'BuildUser']) {
          sh 'echo "${BUILD_USER}"'
        }
      }
    }
  }
}

Вот немного более короткая версия, которая не требует использования переменных среды:

@NonCPS
def getBuildUser() {
    return currentBuild.rawBuild.getCause(Cause.UserIdCause).getUserId()
}

Использование rawBuild требует, чтобы он находился в блоке @NonCPS.

Это можно сделать без плагина (при условии, что JOB_BASE_NAME и BUILD_ID находятся в среде):

def job = Jenkins.getInstance().getItemByFullName(env.JOB_BASE_NAME, Job.class)
def build = job.getBuildByNumber(env.BUILD_ID as int)
def userId = build.getCause(Cause.UserIdCause).getUserId()

Также существует getUserName, которое возвращает полное имя пользователя.

У меня это работает без плагина Build User:

// get first entry of JSONArray
def buildCause = currentBuild.getBuildCauses()[0]
def buildPrincipal = [type:"unknown", name:""]

if (buildCause._class ==~ /.+BranchEventCause/) {
  def branchCause = currentBuild.getRawBuild().getCause(jenkins.branch.BranchEventCause)
  buildPrincipal = [type:"branch",name:buildCause.shortDescription]

} else
if (buildCause._class ==~ /.+TimerTriggerCause/) {
  def timerCause = currentBuild.getRawBuild().getCause(hudson.triggers.TimerTrigger.TimerTriggerCause)
  buildPrincipal = [type:"timer", name:"Timer event"]

} else
if (buildCause._class ==~ /.+UserIdCause/) {
  def buildUserCause = currentBuild.getRawBuild().getCause(hudson.model.Cause.UserIdCause)
  buildPrincipal = [type:"user", name:buildCause.userId]

} else
// ... other causes

def jobUserId, jobUserName
//then somewhere
wrap([$class: 'BuildUser']) {
    jobUserId = "${BUILD_USER_ID}"
    jobUserName = "${BUILD_USER}"
}
//then
println("Started By: ${jobUserName}")

Мы использовали этот плагин: Создание пользовательских переменных Плагин. Доступно больше переменных.

Я изменил ответ @shawn derik, чтобы заставить его работать в моем конвейере:

    stage("preserve build user") {
            wrap([$class: 'BuildUser']) {
                GET_BUILD_USER = sh ( script: 'echo "${BUILD_USER}"', returnStdout: true).trim()
            }
        }

Затем я могу ссылаться на эту переменную позже, передав ее или в той же области, что и $ {GET_BUILD_USER}. Я установил тот же плагин, о котором идет речь.

Изменить. Я перечитал вопрос - ниже вы увидите только пользователя, выполняющего сборку (что технически часто более интересно), а не того, который запускает build во фронтенде (будь то REST-API или WebUI). Если у вас включено олицетворение Jenkins, то я считаю, что результат должен быть эквивалентным, иначе вы получите только пользователя, которому принадлежит агент jenkins на машине сборки.

Исходный ответ:

Другой способ -

sh 'export jenkins_user=$(whoami)'

Оборотная сторона: зависит от Linux, сложно переносить между несколькими агентами в одной сборке (но тогда контекст аутентификации может отличаться на каждом ведомом устройстве)

Плюс: не нужно устанавливать плагины (что на общих / больших экземплярах Jenkins может быть непросто).

Плагин Build User Vars полезен, когда вы выполняете этап на агенте.

Альтернативой является использование текущего предложения сборки (см. https://code-maven.com/jenkins-get-current-user), который также работает, когда на вашей сцене установлено значение agent none.