Можно ли принимать пользовательские параметры командной строки с помощью Inno Setup

В InnoSetup 5.5.5 (и, возможно, в других версиях) просто передайте все, что хотите, в качестве параметра с префиксом /.

c:\> myAppInstaller.exe /foo=wiggle

и в вашем myApp.iss:

[Setup]
AppName = {param:foo|waggle}

|waggle предоставляет значение по умолчанию, если ни один параметр не соответствует. Inno setup не чувствителен к регистру. Это особенно хороший способ работы с параметрами командной строки: они просто появляются. Хотелось бы, чтобы был такой же удобный способ сообщить пользователям, какие параметры командной строки важны для установщика.

Кстати, это делает ответы @knguyen и @steve-dunn несколько излишними. Вспомогательные функции делают именно то, что делает встроенный синтаксис {param: }.

В дополнение к ответу @DanLocks константа {param:ParamName|DefaultValue} задокументирована в нижней части страницы констант:

http://www.jrsoftware.org/ishelp/index.php?topic=consts

Я нашел это очень удобным для опционального подавления страницы лицензии. Вот все, что мне нужно было добавить (используя Inno Setup 5.5.6(a)):

[code]
{ If there is a command-line parameter "skiplicense=true", don't display license page }
function ShouldSkipPage(PageID: Integer): Boolean;
begin
  Result := False
  if PageId = wpLicense then
    if ExpandConstant('{param:skiplicense|false}') = 'true' then
      Result := True;
end;

Inno Setup напрямую поддерживает переключатели с синтаксисом /Name=Value, используя {param} константу.

Вы можете использовать константу непосредственно в секциях, хотя это использование довольно ограничено.

Пример:

[Registry]
Root: HKCU; Subkey: "Software\My Company\My Program\Settings"; ValueType: string; \
    ValueName: "Mode"; ValueData: "{param:Mode|DefaultMode}"

Скорее всего, вы захотите использовать переключатели в Pascal Script.

Если ваш переключатель имеет синтаксис /Name=Value, проще всего прочитать его значение с помощью ExpandConstant function< /а>.

if ExpandConstant('{param:Mode|DefaultMode}') = 'DefaultMode' then
begin
  Log('Installing for default mode');
end
  else
begin
  Log('Installing for different mode');
end;

Если вы хотите использовать значение переключателя для переключения записей в разделах, вы можете использовать Check параметр< /a> и вспомогательная функция, например:

[Files]
Source: "Client.exe"; DestDir: "{app}"; Check: SwitchHasValue('Mode', 'Client')
Source: "Server.exe"; DestDir: "{app}"; Check: SwitchHasValue('Mode', 'Server')

[Code]

function SwitchHasValue(Name: string; Value: string): Boolean;
begin
  Result := CompareText(ExpandConstant('{param:' + Name + '}'), Value) = 0;
end;

Использование может использовать функцию CmdLineParamExists из ответа @TLama на Передача условного параметра в Inno Setup

function CmdLineParamExists(const Value: string): Boolean;
var
  I: Integer;  
begin
  Result := False;
  for I := 1 to ParamCount do
    if CompareText(ParamStr(I), Value) = 0 then
    begin
      Result := True;
      Exit;
    end;
end;

Очевидно, вы можете использовать эту функцию в Pascal Script:

if CmdLineParamExists('/DefaultMode') then
begin
  Log('Installing for default mode');
end
  else
begin
  Log('Installing for different mode');
end;

Но вы можете использовать его даже в разделах, чаще всего используя параметр Check:

[Files]
Source: "MyProg.hlp"; DestDir: "{app}"; Check: CmdLineParamExists('/InstallHelp')

Связанная проблема:
Добавить определяемые пользователем параметры командной строки в /? окно

Если вы хотите проанализировать аргументы командной строки из кода в inno, используйте метод, подобный этому. Просто вызовите скрипт inno из командной строки следующим образом:

c:\MyInstallDirectory>MyInnoSetup.exe -myParam parameterValue

Затем вы можете вызывать GetCommandLineParam таким образом, где вам это нужно:

myVariable := GetCommandLineParam('-myParam');

{ ================================================================== }
{ Allows for standard command line parsing assuming a key/value organization }
function GetCommandlineParam (inParam: String):String;
var
  LoopVar : Integer;
  BreakLoop : Boolean;
begin
  { Init the variable to known values }
  LoopVar :=0;
  Result := '';
  BreakLoop := False;

  { Loop through the passed in arry to find the parameter }
  while ( (LoopVar < ParamCount) and
          (not BreakLoop) ) do
  begin
    { Determine if the looked for parameter is the next value }
    if ( (ParamStr(LoopVar) = inParam) and
         ( (LoopVar+1) <= ParamCount )) then
    begin
      { Set the return result equal to the next command line parameter }
      Result := ParamStr(LoopVar+1);

      { Break the loop }
      BreakLoop := True;
    end;

    { Increment the loop variable }
    LoopVar := LoopVar + 1;
  end;
end;

Это функция, которую я написал, которая является улучшением ответа Стивена Данна. Вы можете использовать его как:

c:\MyInstallDirectory>MyInnoSetup.exe /myParam="parameterValue"

myVariable := GetCommandLineParam('/myParam');

{ util method, equivalent to C# string.StartsWith }
function StartsWith(SubStr, S: String): Boolean;
begin
  Result:= Pos(SubStr, S) = 1;
end;

{ util method, equivalent to C# string.Replace }
function StringReplace(S, oldSubString, newSubString: String): String;
var
  stringCopy: String;
begin
  stringCopy := S; { Prevent modification to the original string }
  StringChange(stringCopy, oldSubString, newSubString);
  Result := stringCopy;
end;

{ ================================================================== }
function GetCommandlineParam(inParamName: String): String; 
var
   paramNameAndValue: String;
   i: Integer;
begin
   Result := '';

   for i := 0 to ParamCount do
   begin
     paramNameAndValue := ParamStr(i);
     if (StartsWith(inParamName, paramNameAndValue)) then
     begin
       Result := StringReplace(paramNameAndValue, inParamName + '=', '');
       break;
     end;
   end;
end;

Да, это возможно, вы можете использовать функцию ParamStr в PascalScript для доступа все параметры командной строки. Функция ParamCount даст вам количество параметров командной строки.

Другой вариант — использовать GetCmdTail.

В ответ на:

«В InnoSetup 5.5.5 (и, возможно, в других версиях) просто передайте все, что хотите, в качестве параметра с префиксом /» «@NickG, да, каждую константу вы можете расширить с помощью функции ExpandConstant»

• Это не тот случай. Попытка использовать параметр командной строки в ExpandConstant в InnoSetup 5.5.6 приводит к ошибке времени выполнения.

PS: я бы добавил комментарий напрямую, но, видимо, мне не хватает "репутации"

Я немного изменил ответ knguyen. Теперь он нечувствителен к регистру (вы можете написать в консоли /myParam или /MYPARAM) и может принимать значение по умолчанию. Также я исправил случай, когда вы получаете больший параметр, чем ожидалось (например: /myParamOther="parameterValue" вместо /myParam="parameterValue". Теперь myParamOther не совпадает).

function GetCommandlineParam(inParamName: String; defaultParam: String): String; 
var
   paramNameAndValue: String;
   i: Integer;
begin
   Result := defaultParam;

   for i := 0 to ParamCount do
   begin
     paramNameAndValue := ParamStr(i);
     if  (Pos(Lowercase(inParamName)+'=', AnsiLowercase(paramNameAndValue)) = 1) then
     begin
       Result := Copy(paramNameAndValue, Length(inParamName)+2, Length(paramNameAndValue)-Length(inParamName));
       break;
     end;
   end;
end;

Я нашел ответ: GetCmdTail.

Вы можете передавать параметры сценариям установки. Установите препроцессор Inno Setup и прочитайте документацию по передаче пользовательских параметров командной строки.