Как реализовать этап Post-Build с помощью плагина Jenkins Pipeline?

Лучше всего использовать действие после сборки в скрипте конвейера.

Обработка сбоев
Декларативный конвейер поддерживает надежную обработку сбоев по умолчанию через свой раздел сообщений, который позволяет объявлять ряд различных «условий публикации», таких как: всегда, нестабильно, успешно, сбой и изменено. В разделе «Синтаксис конвейера» содержится более подробная информация о том, как использовать различные условия публикации.

Jenkinsfile (декларативный конвейер)

pipeline {
    agent any
    stages {
        stage('Test') {
            steps {
                sh 'make check'
            }
        }
    }
    post {
        always {
            junit '**/target/*.xml'
        }
        failure {
            mail to: [email protected], subject: 'The Pipeline failed :('
        }
    }
}

Документация находится ниже https://jenkins.io/doc/book/pipeline/syntax/#post

Если вы используете try / catch и хотите, чтобы сборка была помечена как нестабильная или неудачная, вы должны использовать currentBuild.result = 'UNSTABLE' и т. Д. Я считаю, что некоторые плагины, такие как плагин JUnit Report, установят это для вас, если обнаружит, что не удалось результаты тестов в junit. Но в большинстве случаев вам придется настраивать его самостоятельно, если вы обнаруживаете ошибки.

Второй вариант, если вы не хотите продолжать, - это повторно выбросить ошибку.

stage 'build'
... build
try {
    ... tests
} catch(err) {
    //do something then re-throw error if needed.
    throw(err)
}
stage 'post-build'
...

FWIW, если вы используете скриптовые конвейеры, а не декларативно, вы должны использовать блок try/catch/finally, как предлагается в других ответах. В блоке finally, если вы хотите имитировать то, что делает декларативный конвейер, вы можете либо поместить следующее непосредственно в блок, либо сделать его функцией и вызвать эту функцию из вашего блока finally:

def currResult = currentBuild.result ?: 'SUCCESS'
def prevResult = currentBuild.previousBuild?.result ?: 'NOT_BUILT'

// Identify current result
boolean isAborted = (currResult == 'ABORTED')
boolean isFailure = (currResult == 'FAILURE')
boolean isSuccess = (currResult == 'SUCCESS')
boolean isUnstable = (currResult == 'UNSTABLE')

boolean isChanged = (currResult != prevResult)
boolean isFixed = isChanged && isSuccess && (prevResult != 'ABORTED') && (prevResult != 'NOT_BUILT')
boolean isRegression = isChanged && currentBuild.resultIsWorseOrEqualTo(prevResult)

onAlways()
if (isChanged) {
    onChanged()
    if (isFixed) {
        onFixed()
    } else if (isRegression) {
        onRegression()
    }
}
if (isSuccess) {
    onSuccess()
} else {
    if (isAborted) {
        onAborted()
    }
    onUnsuccessful()
    if (isFailure) {
        onFailure()
    }
    if (isUnstable) {
        onUnstable()
    }
}
onCleanup()

Различные вызовы onXYZ() - это функции, которые вы должны определить для обработки этого конкретного условия вместо использования более удобного синтаксиса декларативных блоков post.

try-catch блоки могут быть настроены для обработки ошибок, как в реальном коде приложения.

Например:

try {
    node {
        sh 'sleep 20' // <<- can abort here
    }
} catch (Exception e) {
    println 'catch'
} finally {
    println 'finally'
}

node {
    println 'second'
}

try {
    node {
        sh 'sleep 20' // <<- can abort here again
    }
} catch (Exception e) {
    println 'catch'
} finally {
    println 'finally'
}

А вот пример вывода с двумя прерываниями.

Started by user me
Replayed #3
[Pipeline] node
Running on my-node in /var/lib/jenkins-slave/workspace/my-job
[Pipeline] {
[Pipeline] sh
[my-job] Running shell script
+ sleep 20

Aborted by me

Sending interrupt signal to process

/var/lib/jenkins-slave/workspace/my-job@tmp/durable-9e1a15e6/script.sh: line 2: 10411 Terminated              sleep 20
[Pipeline] }
[Pipeline] // node
[Pipeline] echo
catch
[Pipeline] echo
finally
[Pipeline] node
Running on my-node in /var/lib/jenkins-slave/workspace/my-job
[Pipeline] {
[Pipeline] echo
second
[Pipeline] }
[Pipeline] // node
[Pipeline] node
Running on my-node in /var/lib/jenkins-slave/workspace/my-job
[Pipeline] {
[Pipeline] sh
[my-job] Running shell script
+ sleep 20

Aborted by me

Sending interrupt signal to process
/var/lib/jenkins-slave/workspace/my-job@tmp/durable-d711100c/script.sh: line 2: 10416 Terminated              sleep 20
[Pipeline] }
[Pipeline] // node
[Pipeline] echo
catch
[Pipeline] echo
finally
[Pipeline] End of Pipeline
Finished: ABORTED

Конечно, это работает для любых исключений, происходящих во время выполнения.