Программный поиск каталога установки VS2017

Вы можете использовать инструмент vswhere, чтобы получить местоположение VS2017.

Пример:

@echo off

rem VS2017U2 contains vswhere.exe
if "%VSWHERE%"=="" set "VSWHERE=%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"

for /f "usebackq tokens=*" %%i in (`"%VSWHERE%" -latest -products * -requires Microsoft.Component.MSBuild -property installationPath`) do (
  set InstallDir=%%i
)

if exist "%InstallDir%\MSBuild\15.0\Bin\MSBuild.exe" (
  "%InstallDir%\MSBuild\15.0\Bin\MSBuild.exe" %*
)

Подробнее об этом можно прочитать здесь: https://blogs.msdn.microsoft.com/heaths/2017/02/25/vswhere-available/

Visual Studio 2017 поддерживает параллельную установку без реестра всех SKU (Enterprise, Professional и Community).

Установщики MSI могут запрашивать через API, описанные здесь: https://blogs.msdn.microsoft.com/heaths/2016/09/15/changes-to-visual-studio-15-setup/

Примеры здесь:

• https://code.msdn.microsoft.com/Visual-Studio-Setup-0cedd331
• https://github.com/microsoft/vs-setup-samples

Решение KindDragon не совсем сработало для меня из-за «функции отложенного расширения» пакета. (WAT)

Вот мой код, совместимый с VS 2017 15.2 (для установки vswhere.exe)

SETLOCAL EnableDelayedExpansion

if not exist "%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" (
  echo "WARNING: You need VS 2017 version 15.2 or later (for vswhere.exe)"
)

for /f "usebackq tokens=*" %%i in (`"%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" -latest -products * -requires Microsoft.Component.MSBuild -property installationPath`) do (
  set InstallDir=%%i
)

if exist "!InstallDir!\VC\Auxiliary\Build\vcvars64.bat" (
  call "!InstallDir!\VC\Auxiliary\Build\vcvars64.bat"
) else (
  echo "Could not find !InstallDir!\VC\Auxiliary\Build\vcvars64.bat"
)

Особо обратите внимание на использование SETLOCAL EnableDelayedExpansion и! InstallDir!

Что ж, vswhere.exe на самом деле не предоставляет больше, чем путь установки версии Visual Studio. Вот мой фрагмент Interix из файла .profile от 2008 года, который делает то же самое с небольшим обновлением (сценарий оболочки):

if [[ -n $PROCESSOR_ARCHITEW6432 || $PROCESSOR_ARCHITECTURE != "x86" ]]; then
  hkeybase='HKLM\SOFTWARE\Wow6432Node\Microsoft\'
else
  hkeybase='HKLM\SOFTWARE\Microsoft\'
fi
for vsver in "15.0" "14.0" "12.0" "11.0" "10.0" "9.0" "8.0"; do
  _vsinstalldir=$(reg.exe query ${hkeybase}'VisualStudio\SxS\VS7' -v $vsver 2>/dev/null \
   | sed -n 's|.*REG_SZ *\([ [:print:]]*\).*|\1|p' | sed 's|\\|/|g')
if [[ -n $_vsinstalldir ]]; then break; fi
done; unset vsver

Это перечисляет установки Visual Studio, отдавая предпочтение последней версии раздела реестра.

HKLM\SOFTWARE\Microsoft\VisualStudio\SxS\VS7

Все еще работаю с Visual Studio 2017. Было бы легко перевести на синтаксис cmd. Запросить реестр проще и не требует vswhere.exe на вашем пути, что благоприятно для IMO.

Теперь поиск текущего экземпляра Visual C ++ и пакетов SDK - это совсем другая задача. : D

Общий вывод на случай, если вам интересно:

C:/Program Files (x86)/Microsoft Visual Studio/2017/Enterprise/

У меня было дьявольское время, пытаясь изменить ответ Срекеля, чтобы искать только VS2017. Примечание. Если вы поместите оператор «for» ниже внутри блока «if», он приведет к повреждению escape-символов и не будет работать.

SETLOCAL EnableDelayedExpansion

if not exist "%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" (
  echo "WARNING: You need VS 2017 version 15.2 or later (for vswhere.exe)"
)

set vswherestr=^"!ProgramFiles(x86)!\Microsoft Visual Studio\Installer\vswhere.exe^" -version [15.0,16.0^^) -products * -requires Microsoft.Component.MSBuild -property installationPath
for /f "usebackq tokens=*" %%i in (`!vswherestr!`) do (  
  set BUILDVCTOOLS=%%i\Common7\Tools
  echo BUILDVCTOOLS: !BUILDVCTOOLS!
  if not exist !BUILDVCTOOLS!\VsDevCmd.bat (
    echo Error: Cannot find VS2017 Build Tools
    goto :buildfailed
  )
  call "!BUILDVCTOOLS!\VsDevCmd.bat"
)    

Могу я порекомендовать свой пакет get-vs2017-path, в котором используются только встроенные инструменты Windows (и хотя он построен как пакет NPM, у него нет зависимостей, а папка инструментов работает автономно)

См. Следующий ответ здесь:

https://stackoverflow.com/a/55754831/2338477

Вы можете использовать любой инструмент командной строки для запроса местоположения Visual Studio, но я также предоставляю программный способ запроса местоположения Visual Studio. Код основан на vswhere исходном коде, но упрощен.

У нас всего 3 редакции Visual Studio.

• \Сообщество
• \ Профессиональный
• \Предприятие

Таким образом, мы можем все немного упростить.
Вот несколько протестированных сценариев CMD.

@SET env_all_vs2017_root=%ProgramFiles(x86)%\Microsoft Visual Studio\2017
@SET env_vs2017_path="%env_all_vs2017_root%\Professional"
@IF NOT EXIST %env_vs2017_path%  SET env_vs2017_path="%env_all_vs2017_root%\Community"
@IF NOT EXIST %env_vs2017_path%  SET env_vs2017_path="%env_all_vs2017_root%\Enterprise"
@REM Let's fail laudly
@IF NOT EXIST %env_vs2017_path%  SET "env_vs2017_path=Visual Studio 2017 install path was not found by %~nx0"

@REM  You may want to remove quotes
@SET unquoted=%env_vs2017_path:"=%


@REM  And now let's see the result and PAUSE

@ECHO VS 2017 install path is
@ECHO %unquoted%

@PAUSE

Вы можете использовать этот фрагмент PowerShell для поиска каталога установки VS2017:

$vssetup_path = "$([Environment]::GetFolderPath("MyDocuments"))\WindowsPowerShell\Modules\VSSetup"
if (-not (Test-Path $vssetup_path -pathType container))
{
    iwr https://github.com/Microsoft/vssetup.powershell/releases/download/1.0.36-rc/VSSetup.zip -OutFile "$env:TEMP\VSSetup.zip"
    Expand-Archive "$env:TEMP\VSSetup.zip" $vssetup_path
}
$vs2017 = Get-VSSetupInstance -All | Select-VSSetupInstance -Require 'Microsoft.VisualStudio.Workload.NativeDesktop' -Version '[15.0,16.0)' -Latest
"Installation Path: " + $vs2017.InstallationPath
#`vsdevcmd.bat -arch=x86` or `vsdevcmd.bat -arch=amd64` can be used to setup path's to VC++ compiler
"VsDevCmd.bat Path: " + $vs2017.InstallationPath + "\Common7\Tools\VsDevCmd.bat"

Я использую powershell, как предложил KindDragon

$Is64bitOs = $env:PROCESSOR_ARCHITEW6432 -eq 'AMD64';
if ($Is64bitOs){
    $registryPath = "Registry::HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\VisualStudio\14.0";
}
else {
    $registryPath = "Registry::HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\VisualStudio\14.0";
}

$VSInstallDir = (Get-ItemProperty -Path Registry::HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\VisualStudio\14.0 -Name ShellFolder).ShellFolder;