Формула СУММЕСЛИМН в VBA с ‹

Во-первых, чтобы получить <$F$1 внутри формулы, я использую Chr(34), чтобы добавить круглую скобку "" внутри формулы.

Кроме того, вы путаете несколько вещей:

• Старайтесь избегать использования Worksheets("Database").Activate и Worksheets("Sheet2").Activate, а вместо этого используйте полные рабочие листы и диапазоны, например: With Worksheets("Database") и внутри lastCode = .Range("O" & .Rows.Count).End(xlUp).Row.
• У вас есть Sheet2 и Worksheets("Sheet2"), эти два не всегда означают один и тот же рабочий лист. Вы можете переименовать Sheet2 (по кодовому имени) в «Что-то», и это будет ваш второй лист, и переименовать Sheet3 (по кодовому имени) в «Лист2», и у вас возникнет проблема. Так что решите, какой метод вы хотите использовать (я предпочитаю использовать Worksheets("Sheet2")).
• Dim lastCode, lastFiltCode As Integer означает, что lastCode на самом деле Variant, а lastFiltCode это Integer. В любом случае лучше использовать Long для обеих этих переменных, когда вы пытаетесь получить последнюю строку.

Код

Option Explicit

Sub SumGroups()

Dim lastCode As Long, lastFiltCode As Long

'Determine Last Row in Column O (Unfiltered Codes)
With Worksheets("Database")
    lastCode = .Range("O" & .Rows.Count).End(xlUp).Row

    'Filter Unique Codes into Column A Sheet2
    .Range("O1:O" & lastCode).AdvancedFilter Action:=xlFilterCopy, _
            CopyToRange:=Worksheets("Sheet2").Range("A1"), Unique:=True        
End With

With Worksheets("Sheet2")
    'Determine last Row in Column A (Filtered Codes)
    lastFiltCode = .Range("A" & .Rows.Count).End(xlUp).Row

    'Place SUMIF Formulas in Columns Sheet2
    .Range("B2:B" & lastFiltCode).Formula = _
        "=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2)"

    .Range("D2:D" & lastFiltCode).Formula = _
        "=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2,Database!$I$2:$I$" & lastCode & "," & Chr(34) & "<" & Chr(34) & "&$F$1)"

    .Range("F2:F" & lastFiltCode).Formula = _
        "=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode & ",A2,Database!$I$2:$I$" & lastCode & ",$F$1)"
End With

End Sub

Просто чтобы уточнить, почему другие ответы работают:

SumIf (а также различные другие функции Excel, требующие строковых операторов (таких как CountIf) ожидают, что логические операторы и их последующие операторы будут выражены в виде строки. То есть должны быть заключены в речевые метки, например, «myString».

Поскольку формула также является строкой, например. ActiveCell.Formula = "=If(A1=3, 1, 0)" компилятор путается в том, какой набор кавычек обозначает строку. Так например это не будет работать: ActiveCell.Formula = "=If(A1=3, "Yes", "No")".

Технически способ справиться с этим состоит в том, чтобы заключить требуемую кавычку в собственные кавычки; """ myValue """.

Однако это быстро сбивает с толку. Вместо этого используйте функцию Character, чтобы вернуть требуемый символ. . В данном случае 34; chr(34) & myvalue & (chr34).

Worksheets("Sheet2").Range("D2:D" & lastFiltCode).Formula = _
"=SUMIFS(Database!$M$2:$M$" & lastCode & ",Database!$O$2:$O$" & lastCode &      ",A2,Database!$I$2:$I$" & lastCode & ","" < "" &$F$1)"

Это сделает это. поставить ‹ в кавычках.