State Monad для сохранения доски в игре

Если вы поменяете порядок аргументов на play, у вас будет функция типа:

Move -> Board -> Board

Что вы можете частично применить с Move, чтобы получить один из типов:

Board -> Board

Вы можете преобразовать это в действие на State, используя modify :: (s -> s) -> State s () для изменения доски:

playing :: Move -> State Board ()
playing move = modify (play move)

Одно из решений - преобразователи монад - звучит страшнее, чем есть на самом деле. Вы можете использовать StateT вместо IO, StateT для сохранения состояния игры и IO, чтобы запрашивать у пользователя ходы. Например:

import Control.Monad.Trans.Class (lift)
import Control.Monad.Trans.State (evalStateT, gets, modify)

-- Get a move from the user.
getMove :: IO Move
getMove = do
  line <- getLine
  -- (Your implementation of parsing moves here.)

-- The initial state of the board.
initialBoard :: Board
initialBoard = -- ...

-- Whether the board represents a completed game.
boardDone :: Board -> Bool
boardDone board = -- ...

-- Main game loop.
gameLoop :: IO ()
gameLoop = evalStateT loop initialBoard
  where
    loop = do
      move <- lift getMove
      modify (play move)
      done <- gets boardDone
      if done then pure () else loop

Вы используете lift для преобразования обычного IO действия в StateT Board IO действие, modify :: (Monad m) => (s -> s) -> StateT s m () для изменения состояния и gets :: (Monad m) => (s -> a) -> StateT s m a для чтения свойств текущего состояния. loop либо хвостом зовет себя продолжить игру, либо возвращается.

Используя структуру и имена в отредактированном вопросе:

playing :: IO ()
playing = evalStateT loop initialBoard
  where

    loop :: StateT Board IO ()
    loop = do
      printBoard
      move <- lift promptMove
      modify (play move)
      ended <- gets gameEnded
      if ended
        then lift $ putStrLn "You win!"
        else loop

    printBoard :: StateT Board IO ()
    printBoard = do
      lift $ putStrLn $ "The board looks like:"
      board <- get
      lift $ putStrLn $ showBoard board

    promptMove :: IO Move
    promptMove = do
      putStr "Indicate a move: "
      move <- getLine
      if validMove move
        then pure $ getMove move
        else do
          putStrLn "Invalid move."
          promptMove