Ну, я думаю, если он действительно должен быть буквенно-цифровым и уникальным, это путь:

Этот код генерирует случайную строку символов на основе текущего времени (например, ответ @paul-bica), только он кодирует их буквенно-цифровым образом и использует таймер, чтобы получить доли секунды для достижения 12 символов). Таким образом, вы сможете генерировать несколько случайных строк в секунду.

Просто вызовите UniqueTimeBasedString(), чтобы получить строку. (Обратите внимание, что если вы используете эту функцию в запросе, Access кэширует результат, и он вообще не будет уникальным).

Public Function UniqueTimeBasedString() As String
    Dim alphanumericCharacters As String
    alphanumericCharacters = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
    Dim timeString As String
    timeString = Format(Now, "yymmddhhmmss") & Getmtimestring(6)
    Dim c As Integer
    Dim intTimepart As Integer
    c = 1
    Do While c < Len(timeString)
        intTimepart = CInt(Mid(timeString, c, 3))
        c = c + 3
        UniqueTimeBasedString = UniqueTimeBasedString & Mid(alphanumericCharacters, Int(intTimepart / 61) + 1, 1) & Mid(alphanumericCharacters, intTimepart Mod 61 + 1, 1)
    Loop
End Function

Public Function Getmtimestring(length As Integer) As String
    Dim mtime As Double
    mtime = Timer()
    Dim mtimeLng As Long
    mtimeLng = Int((mtime - Int(mtime)) * (10 ^ length))
    Getmtimestring = CStr(mtimeLng)
    Do While Len(Getmtimestring) < length
        Getmtimestring = "0" & Getmtimestring
    Loop
End Function

Примечания:

1. Timer() не совсем точен, и теоретически это может вызвать проблемы
2. Этот код несовместим с OS X, но это не будет проблемой, если вы останетесь ограниченным доступом (Getmtimestring просто вернет нули)
3. Вам действительно стоит поговорить с вашим боссом. Просить вас сделать что-то, для чего вы на самом деле не подходите, со сжатыми сроками и без возможности использовать немного другое решение — нездоровое поведение на рабочем месте.
4. Строка содержит закодированное время и может быть декодировано. Не сообщайте об этом, если хотите, чтобы время создания строки было секретным.

Есть несколько решений этой проблемы, но мне нравится это:

Public Function newguidx() As String
    With CreateObject("Scriptlet.TypeLib")
        newguidx = Left(.Guid, 38)
    End With  
End Function

Он создает GUID. Они не уникальны сами по себе, но вы можете прочитать на странице Википедии, что они вполне могут быть таковыми. Вы можете использовать Replace, чтобы удалить знаки {}-, если хотите.

Кроме того, поскольку формат стандартизирован, большинству программистов будет понятно, что это такое.

Очевидно, вы можете обрезать символы, чтобы получить желаемую длину, и это увеличит ваши шансы найти дубликат.

Редактировать:

К сожалению, доступ к Scriptlet.TypeLib в настоящее время заблокирован по умолчанию из соображений безопасности. См. Ошибка MS Access VBA: ошибка времени выполнения "70" Отказано в доступе для получения информации об этом и Как я могу генерировать идентификаторы GUID в Excel? для хорошего обзора нескольких методов создания GUID.

Мои личные предпочтения:

Public Function CreateGUID() As String
    Do While Len(CreateGUID) < 32
        If Len(CreateGUID) = 16 Then
            '17th character holds version information
            CreateGUID = CreateGUID & Hex$(8 + CInt(Rnd * 3))
        End If
        CreateGUID = CreateGUID & Hex$(CInt(Rnd * 15))
    Loop
    CreateGUID = "{" & Mid(CreateGUID, 1, 8) & "-" & Mid(CreateGUID, 9, 4) & "-" & Mid(CreateGUID, 13, 4) & "-" & Mid(CreateGUID, 17, 4) & "-" & Mid(CreateGUID, 21, 12) & "}"
End Function

Используйте строку даты и времени:

• Формула: =TEXT(NOW(),"yymmddhhmmss") -> 170705161201

• VBA: Debug.Print Format(Now, "yymmddhhmmss")