Powershell в пакетном файле — как избежать метасимволов?

@echo off
:: Do NOT use setlocal ENABLEDELAYEDEXPANSION, because it would cause
:: misinterpretation of  "!" chars. in filenames.    
setlocal

:: Parse the file path given as %1 (the first argument) into its folder path and filename.
:: Be sure to pass the %1 argument *double-quoted* to prevent up-front interpretation 
:: by cmd.exe; e.g.:
::   someBatchFile "c:\tmp\foo.txt" or someBatchFile "%file%"
:: Note that %~dp1 always returns a path with a trailing "\".
set "fpath=%~dp1"
set "fname=%~nx1"

:: Determine the destination folder
set "dest=E:\"

:: Use robocopy to copy the file to the destination dir. with timestamps preserved.
:: Syntax is: <source-dir> <dest-dir> <filename-or-wildcard> ...
:: IMPORTANT: To avoid problems with paths that end in "\", always follow
::            a variable reference inside "..." with a *space* (a trick discovered by
::            Ed999 himself).
robocopy "%fpath% " "%dest% " "%fname%"

• Хотя robocopy в основном используется для копирования целых каталогов, он действительно позволяет копировать отдельные файлы с помощью выражений с подстановочными знаками, указанных начиная с третьего позиционного аргумента. , как "%fname%" выше.
  Учитывая, что robocopy, в отличие от PowerShell, не учитывает подстановочные знаки [ и ] < em>метасимволы, этот подход должен работать (у вас возникнут проблемы только в том случае, если ваши имена файлов будут содержать встроенные символы * или ?, что маловероятно).

• Трюк с завершающим пробелом (например, "%fpath% ") необходим, потому что robocopy, как и большинство утилит командной строки, обрабатывает \" в конце аргумента как экранированный ", что прерывает команду. Строго говоря, правильное решение состоит в том, чтобы удвоить конечные \ (например, "E:\\"), но вы можете обойтись без добавления пробела, потому что любой конечный пробел в путях < em>игнорируется. Таким образом, простой способ сделать такие вызовы надежными — всегда использовать "%var% " (конечный пробел перед закрывающей двойной кавычкой) при передаче путей к папкам.

• robocopy не имеет переключателя, аналогичного /V, который заставляет его проверять правильность копирования файла, но, по крайней мере, в соответствии с этот пост в блоге — предварительное выполнение verify on должно иметь тот же эффект.

Если вам все еще нужно скопировать метку времени создания через PowerShell:

powershell -command "(Get-Item -LiteralPath '%dest%%fname%').CreationTime=(Get-Item -LiteralPath '%fpath%%fname%').CreationTime"

Предупреждение: если есть вероятность, что ваши имена файлов содержат ' символов. (одинарные кавычки/апострофы), вы должны сначала экранировать их, удвоив их (например, %fname:'=''% возвращает значение %fname% со всеми удвоенными экземплярами '):

powershell -command "(Get-Item -LiteralPath '%dest:'=''%%fname:'=''%').CreationTime=(Get-Item -LiteralPath '%fpath:'=''%%fname:'=''%').CreationTime"

• Обратите внимание, что вся команда заключена в "...", чтобы предотвратить нарушение команды метасимволами cmd.exe (такими как &), которые могут содержаться в значениях переменных.^[1]

• Внутри командной строки используется '...', чтобы убедиться, что значения переменных обрабатываются PowerShell как литералы (например, если вы использовали "..." и имя файла содержало $, результат было бы неожиданно).

• -LiteralPath гарантирует, что Get-Item интерпретирует путь к файлу как литерал, в то время как
  параметр -Path подразумевается, когда вы передаете путь позиционно, а пути, переданные в< br> -Path интерпретируются как выражения с подстановочными знаками, что может вызвать проблемы с метасимволами подстановки PowerShell, такими как [ и ].

• Нет необходимости сначала преобразовывать значение свойства .CreationTime исходного файла в строку даты и времени; вы можете просто присвоить его непосредственно свойству .CreationTime целевого файла, имеющему тип [System.DateTime].

^[1] Цитируя головные боли:

• Заключить только ссылки на переменные в двойные кавычки с экранированием \, как в вопросе (\"%dest%\%fname%\"), недостаточно, поскольку это подвергает значение нормализации пробелов , что означает, что прогоны из более одного пробела нормализуются к одному пробелу.

• Хотя дополнительно включение команды в целом в "..." в принципе помогает, cmd.exe тогда не распознает общую строку как одну строку в двойных кавычках, и в этом случае метасимволы такие как & в значениях переменных могут сломать команду; например,
  powershell.exe -command "echo \"a b\"" работает нормально, точно сохраняя пробелы, но
  powershell.exe -command "echo \"a & b\"" ломается из-за &.

  • Using \"" instead of \" solves the metacharacter problem, but reintroduces whitespace normalization:
    powershell.exe -command "echo \""a & b\""" yields a & b

• Таким образом, использование строк '...' PowerShell внутри общей строки "..." — самый простой способ сделать команду надежной: вам нужно всего лишь экранировать ' экземпляров в значениях переменных.

В конечном счете, это было лучшее решение, которое я мог придумать в пакетном файле.

Он работает со 100% надежностью благодаря использованию команд REN и SET в командной оболочке Windows, которые лишены недостатков ROBOCOPY или POWERSHELL.

@echo off

::  **  INPUT File **
    SET file=%1

::  **  Destination Directory **
    SET dest=C:\Users\%Username%\Desktop\test

::  **  Copy using Command Shell **
    COPY /V /Y  %file% "%dest%"

::  **  Location of PowerShell **
    SET PowerShell=C:\WINDOWS\system32\WindowsPowerShell\v1.0\powershell.exe -NoProfile

::  ** Store PATH & NAME of source file (WITHOUT quotation marks) **
    FOR /F "usebackq delims==" %%A IN ('%file%') DO (
          SET fpath=%%~dpA
          SET fname=%%~nxA
    )

::  ** Rename the Files **
    REN "%fpath%%fname%" temp1
    REN "%dest%\%fname%" temp2

::  ** Set CREATED date of output file **
::  NB: Will fail if MONTHS (MM) is identical to MINUTES (mm)
    %PowerShell% (Get-Item \""%dest%\temp2\"").CreationTime=$(Get-Item \""%fpath%temp1\"" ^| Select-Object -ExpandProperty CreationTime ^| Get-Date -f \"MM-dd-yyyy HH:mm:ss\")

::  ** Set MODIFIED date of output file **
::  NB: Will fail if MONTHS (MM) is identical to MINUTES (mm)
    %PowerShell% (Get-Item \""%dest%\temp2\"").LastWriteTime=$(Get-Item \""%fpath%temp1\"" ^| Select-Object -ExpandProperty LastWriteTime ^| Get-Date -f \"MM-dd-yyyy HH:mm:ss\")

::  ** Wait **
    ::  No, I have no idea why it doesn't work without this...
    echo. & echo Wait 15 Seconds ... & echo.
    @CHOICE /T 15 /C yn /D y > NUL

::  ** Restore ORIGINAL filenames **
    REN "%fpath%temp1" "%fname%"
    REN "%dest%\temp2" "%fname%"

Вместо того, чтобы мутить воду, вмешиваясь в предыдущие ответы, вот мой последний «взгляд» на эту проблему.

Месяц дополнительных возни привел меня к тому, что я отказался от своего предыдущего решения (которое отлично сработало!) в пользу решения, в котором не нужно переименовывать файлы (хотя я обнаружил, что настоящий отличная идея: вы не сможете столкнуться с опасными метасимволами, если примете мое простое решение, переименовав файлы в любое безопасное временное имя перед запуском Powershell или Robocopy).

Но ниже приведено решение, основанное на приведенных выше идеях, которое после месяца тестирования еще не дало никаких сбоев. И он не использует никаких "неавторизованных" ярлыков, переименовывая файл!

Следующий командный файл теперь находится в моей папке отправки Windows 7, поэтому он всегда доступен из контекстного меню проводника Windows.

Папка для отправки в Windows 7:

C:\Users\%Username%\AppData\Roaming\Microsoft\Windows\SendTo

.

@echo off

::  *** Copy file including its CREATED date & MODIFIED date ***

::  File : Drag-and-Drop
    SET file=%1

::  Destination Directory
    SET dest=E:\

::  ** Safety Checks **
    ATTRIB -R -A -S -H  %file%

::  ** Store PATH & NAME of file (WITHOUT quotation marks) **
    FOR /F "usebackq delims==" %%A IN ('%file%') DO (
      SET fpath=%%~dpA
      SET fname=%%~nxA
      SET  name=%%~nA
      SET   ext=%%~xA
    )

    ::  *** POWERSHELL : File only ***

    ::  ** Copy File **
    COPY /V /Y  %file% "%dest%"

    ::  ** Location of PowerShell **
    SET PowerShell=C:\WINDOWS\system32\WindowsPowerShell\v1.0\powershell.exe -NoProfile

    ::  ** Set CREATED date of copy **
    %PowerShell% -command "(Get-Item -LiteralPath '%dest:'=''%\%fname:'=''%').CreationTime=(Get-Item -LiteralPath '%fpath:'=''%%fname:'=''%').CreationTime"

    ::  ** Set MODIFIED date of copy **
    %PowerShell% -command "(Get-Item -LiteralPath '%dest:'=''%\%fname:'=''%').LastWriteTime=(Get-Item -LiteralPath '%fpath:'=''%%fname:'=''%').LastWriteTime"

    ::  ** Set ACCESSED date of copy **
    %PowerShell% -command "(Get-Item -LiteralPath '%dest:'=''%\%fname:'=''%').LastAccessTime=(Get-Item -LiteralPath '%fpath:'=''%%fname:'=''%').LastAccessTime"

    ::  Open Destination Directory
    C:\Windows\Explorer.exe "%dest%"