Использование нескольких имен файлов в качестве подстановочных знаков в Snakemake

Удалите вызов expand в вашем определении input и output в closest. В настоящее время вы передаете вектор из 20 имен файлов как input.input2 и вектор из 20 имен файлов как output.

То есть ваше правило closest в настоящее время пытается выполнить один раз и создать 20 файлов; тогда как он должен запускаться 20 раз и каждый раз создавать один файл.

В closest вы хотите, чтобы input.input2 был одним файлом, а output - одним файлом при каждом запуске этого правила:

FIRSTPART = [f.split(".")[0] for f in os.listdir("/home/bedfiles") if f.endswith('.bed')]

print("These are the input files:")
print([f + ".bed" for f in FIRSTPART])

MODIFIED = expand("/home/bedfiles/{first}_modified", first=FIRSTPART)
print("These will be created")
print(MODIFIED)

rule all:
   input: MODIFIED

rule closest:
    message: """
        Converts /home/other/merged.txt and /some/dir/xyz.bed
        into /some/dir/xyz_modified
        """

    input:
        input1 = "/home/other/merged.txt",
        input2 = "{prefix}.bed" 

    output:    "{prefix}_modified"  

    shell:
        """ 
        bedtools closest -a {input.input1} -b {input.input2} > {output}
        """

Вот эксперимент:

Переместитесь во временный каталог и в этом каталоге выполните следующие действия:

mkdir bedfiles                                                                  
touch bedfiles/{a,b,c,d}.bed

Затем добавьте в текущий каталог файл с именем Snakefile, содержащий следующий код

import os                                                                         
import os.path
import re

input_dir = "bedfiles"
input_files = [os.path.join(input_dir, f) for f in os.listdir(input_dir)]

print(input_files)                                                                

output_files = [re.sub(".bed$", "_modified", f) for f in input_files]             

print(output_files)                                                               

rule all:                                                                         
    input: output_files                                                           

rule mover:                                                                       
    input: "{prefix}.bed"                                                         
    output: "{prefix}_modified"                                                   
    shell:                                                                        
       """ cp {input} {output} """

Затем запустите его, используя snakemake в командной строке. Snakemake целеустремлен; он работает над тем, как сделать желаемый результат на основе существующих файлов.

Простой: неверный синтаксис относится к отсутствующему , после input1 = "/home/other/merged.txt". Надеюсь, это поможет Марку.