Невозможно использовать значения ListBox в MS Access 2007 для перехода к запросу

Это не идеальный ответ, который я надеялся вам дать, но не могу понять, как использовать запросы с параметрами в команде IN.

Я предполагаю, что ваш список содержит два столбца данных, а значения CarID находятся в первом столбце.

Основная функция называется ProcessQuery и принимает в качестве аргумента ссылку на список:
Public Sub ProcessQuery(myList As ListBox)

Затем вы можете вызвать свой код из события в списке и передать ему ссылку на список.

Private Sub btnSearchCars_Click()
    ProcessQuery Me.listCarID
End Sub  

Затем процедура ProcessQuery просматривает первый столбец, чтобы получить номера индексов, строит SQL, открывает полученный набор записей и извлекает информацию из каждой записи.

Public Sub ProcessQuery(myList As ListBox)

    Dim vItem As Variant
    Dim IDList As String
    Dim qdf As dao.QueryDef
    Dim rst As dao.Recordset

    For Each vItem In myList.ItemsSelected
        'Column 0 is first column in listbox.
        IDList = IDList & "'" & myList.Column(0, vItem) & "',"
    Next vItem
    'Removes the final ,
    IDList = Left(IDList, Len(IDList) - 1)

    'Create a temporary query definition & open the recordset.
    Set qdf = CurrentDb.CreateQueryDef("", _
        "SELECT tblBig.* FROM tblCars INNER JOIN tblBig ON tblCars.Car_ID = tblBig.Car_ID WHERE tblCars.Car_ID IN (" & IDList & ")")
    Set rst = qdf.OpenRecordset

    'Move through the recordset and output the first two fields from each record
    'to the Immediate window.
    With rst
        If Not (.BOF And .EOF) Then
            .MoveFirst
            Do While Not .EOF
                Debug.Print .Fields(0) & " - " & .Fields(1)
                .MoveNext
            Loop
        End If
    End With

End Sub 

Чтобы отобразить результат запроса в виде таблицы, вы можете использовать следующее, но я бы предпочел использовать сохраненный запрос с параметром для IN. Я постараюсь понять это.

Public Sub ProcessQuery(myList As ListBox)

    Dim vItem As Variant
    Dim IDList As String
    Dim qdf As dao.QueryDef
    Dim rst As dao.Recordset

    For Each vItem In myList.ItemsSelected
        'Column 0 is first column in listbox.
        IDList = IDList & "'" & myList.Column(0, vItem) & "',"
    Next vItem
    'Removes the final ,
    IDList = Left(IDList, Len(IDList) - 1)

    'Create a temporary query definition & open the recordset.
    Set qdf = CurrentDb.CreateQueryDef("TempQDF", _
        "SELECT tblBig.* FROM tblCars INNER JOIN tblBig ON tblCars.Car_ID = tblBig.Car_ID WHERE tblCars.Car_ID IN (" & IDList & ")")

    DoCmd.OpenQuery "TempQDF", acViewNormal

End Sub

Я бы посоветовал сначала взглянуть на фактическое генерируемое предложение WHERE ... сохранить отдельную строковую переменную для ее хранения, а затем выгружать ее в Immediate Window, когда она сгенерирована.

Я бы также предложил создать отдельную функцию для возврата значений, выбранных в списке, в виде массива. Что-то типа:

Public Function getListBoxSelection(ctl As Access.ListBox) As Variant
   Dim arr() As Variant
   Dim varItem As Variant, i As Long

   If ctl.ItemsSelected.Count > 0 Then
      ReDim arr(0 To ctl.ItemsSelected.Count - 1)
      i = 0

      For Each varItem In ctl.ItemsSelected
         arr(i) = ctl.ItemData(varItem)
         i = i + 1
      Next varItem

   End If

   getListBoxSelection = arr
End Function

Затем вы бы назвали его генерацией SQL. Что-то типа

whereClause = join(getListBoxSelection(me.listCarID), " AND ")
debug.Print whereClause

qdf.SQL = _
    "select tblBig.* " & _
    "from tblCars " & _
    "inner join tblBig on tblCars.Cat_ID = tblBig.Car_ID " & _
    "where tblCars.Card_ID in (" & whereClause & ")"