Как использовать функцию esp_bt_gap_read_rssi_delta, чтобы получить классический RSSI Bluetooth из ESP32?

После нескольких попыток я заставил работать esp_bt_gap_read_rssi_delta ().

Первое, что нужно понять (если вы еще не получили его), - это обратный вызов / событие. Функция обратного вызова - это функция в вашем коде, которая будет вызываться ESP-IDF, когда происходит что-то особенное (событие). Вы регистрируете свою функцию обратного вызова, вызывая esp_bt_gap_register_callback () после инициализации стека bluetooth.

Когда вы вызываете esp_bt_gap_read_rssi_delta () (после подключения к устройству), он немедленно возвращается со статусом Ok или ошибкой. Фактическое значение RSSI будет возвращено позже фреймворком, вызывающим вашу функцию обратного вызова.

Функция обратного вызова имеет два параметра. Первая идентифицирует произошедшее событие, вторая - данные, связанные с событием. Этот второй параметр является указателем на одну из структур, определенных в объединении esp_bt_gap_cb_param_t.

Вот некоторый скелетный код (не тестовые коды возврата и т. Д.) Для Arduino IDE, использующий BluetoothSerial для соединения:

#include "esp_gap_bt_api.h"
#include "BluetoothSerial.h"

BluetoothSerial SerialBT;
byte addr[6] = { 0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };

void setup() {
  Serial.begin (115200);
  SerialBT.begin();
  esp_bt_gap_register_callback (gap_callback);
}

void loop() {
  delay(100);
  if (SerialBT.hasClient()) {
    esp_bt_gap_read_rssi_delta (addr);
    delay (10000);    
  }
}

void gap_callback (esp_bt_gap_cb_event_t event, esp_bt_gap_cb_param_t *param) {
  if (event == ESP_BT_GAP_READ_RSSI_DELTA_EVT) {
    Serial.println (param->read_rssi_delta.rssi_delta);
  }
}

Итак, окончательное решение моего вопроса (благодаря @dquadros):

//ESP32, Classic Bluetooth, SPP
#include "BluetoothSerial.h"
#include "esp_gap_bt_api.h"
#include <esp_spp_api.h>

BluetoothSerial SerialBT;
byte rssi; //RSSI
byte addr[6] = {0,0,0,0,0,0}; //to keep MAC address of the remote device

//RSSI callback function
void gap_callback (esp_bt_gap_cb_event_t event, esp_bt_gap_cb_param_t *param)
{
  if (event == ESP_BT_GAP_READ_RSSI_DELTA_EVT) rssi = param->read_rssi_delta.rssi_delta;
}

//SPP service callback function (to get remote MAC address)
void spp_callback (esp_spp_cb_event_t event, esp_spp_cb_param_t *param)
{
  if (event == ESP_SPP_SRV_OPEN_EVT) memcpy(addr, param->srv_open.rem_bda, 6);
}

void setup()
{
  Serial.begin(9600);
  SerialBT.begin("ESP32");
  //register RSSI callback function:
  esp_bt_gap_register_callback (gap_callback);
  //register SPP service callback to get remote address:
  SerialBT.register_callback(spp_callback);
}

void loop()
{
  //when we need RSSI call this:
  esp_bt_gap_read_rssi_delta (addr); //now variable rssi contains RSSI level
  byte b = rssi; //etc....
}