Перезаписать элемент вложенного списка с помощью jsonnet

У меня следующий json

{
    "namespace": "monitoring",
    "name": "alok",
    "spec": {
        "replicas": 1,
        "template": {
            "metadata": "aaa",
            "spec": {
                "containers": [
                    {
                        "image": "practodev/test:test",
                        "env": [
                            {
                                "name":"GF_SERVER_HTTP_PORT",
                                "value":"3000"
                            },
                            {
                                "name":"GF_SERVER_HTTPS_PORT",
                                "value":"443"
                            },
                        ]
                    }
                ]
            }
        }
    }
}

Как добавить deployment_env.json с помощью jsonnet?

{
    "env": [
        {
            "name":"GF_AUTH_DISABLE_LOGIN_FORM",
            "value":"false"
        },
        {
            "name":"GF_AUTH_BASIC_ENABLED",
            "value":"false"
        },

    ]
}

Мне нужно добавить его в spec.template.containers [0] .env = deployment_env.json

Для этого я написал нижеприведенный jsonnet. Добавляет новый элемент. Но мне нужно изменить существующий 0-й элемент контейнера в json. Подскажите, как это сделать.

local grafana_envs = (import 'custom_grafana/deployment_env.json');
local grafanaDeployment = (import 'nested.json') + {
    spec+: {
        template+: {
            spec+: {
                containers+: [{
                    envs: grafana_envs.env,
                }]
            }
        }
    },
};
grafanaDeployment

kubernetes json prometheus jsonnet
person Alok Kumar Singh    schedule 26.02.2019    source источник

Ответы (2)


arrow_upward
4
arrow_downward

См. Ниже реализацию, которая позволяет добавлять env в существующий контейнер по его индексу в массиве containers[].

Обратите внимание, что jsonnet гораздо лучше подходит для работы с объектами (т. Е. Словарями / картами), а не с массивами, поэтому требуется искусная обработка через std.mapWithIndex(), чтобы иметь возможность изменять запись из соответствующего индекса.

local grafana_envs = (import 'deployment_env.json');

// Add extra_env to a container by its idx passed containers array
local override_env(containers, idx, extra_env) = (
  local f(i, x) = (
    if i == idx then x {env+: extra_env} else x
  );
  std.mapWithIndex(f, containers)
);
local grafanaDeployment = (import 'nested.json') + {
    spec+: {
        template+: {
            spec+: {
                containers: override_env(super.containers, 0, grafana_envs.env)
            }
        }
    },
};
grafanaDeployment
person jjo    schedule 26.02.2019

arrow_upward
1
arrow_downward

Альтернативная реализация, не полагающаяся на позицию индекса массива, а вместо этого значение image (что имеет здесь больше смысла, поскольку env должно пониматься реализацией изображения)

local grafana_envs = (import 'deployment_env.json');

local TARGET_CONTAINER_IMAGE = 'practodev/test:test';

local grafanaDeployment = (import 'nested.json') + {
  spec+: {
    template+: {
      spec+: {
        containers: [
          // TARGET_CONTAINER_IMAGE identifies which container to modify
          if x.image == TARGET_CONTAINER_IMAGE
          then x { env+: grafana_envs.env }
          else x
          for x in super.containers
        ],
      },
    },
  },
};
grafanaDeployment
person jjo    schedule 06.03.2019