Ошибка QUERY: в ARRAY_LITERAL в литерале массива отсутствовали значения для одной или нескольких строк.

Надеюсь, что кто-то может мне помочь с этим!

Я беру данные из большой таблицы прогнозов доходов и суммирую их в несколько отдельных (более аккуратных) таблиц, чтобы получить таблицу прогнозов с января по декабрь для каждого клиента в основном прогнозе.

Выходные данные будут состоять из:

КЛИЕНТ А

Столбец A: Название проекта.

Столбец B: Статус дохода.

Столбец C: значение января.

Столбец D и далее: значения с февраля по декабрь.

Статус дохода в исходном источнике данных (столбец C): «Контракт», «Предлагается», «Идентифицирован» и «Требуется найти». У клиента A есть только доход по контракту и поиску, поэтому построенная мною формула массива дает ошибку, поскольку не может найти данные для предложенных и идентифицированных.

Исходные данные

ССЫЛКА ЗДЕСЬ: LINK

Столбец G - это название проекта, столбец C - статус дохода, а столбцы L-W - это месяцы с января по декабрь.

Вот моя формула (сокращено только для 2 типов статуса дохода, всего их 4). Я должен добавить, что я пытаюсь настроить сортировку статуса дохода в порядке безопасности прогнозируемого показателя.

={QUERY('2019_MRS Data'!A:W,"select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) where (E='"&A2&"') AND C='Contracted'GROUP BY C,G ORDER BY C label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)'' ",1);QUERY('2019_MRS Data'!A:W,"select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) where (E='"&A2&"') AND C='Proposal'GROUP BY C,G ORDER BY C label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)'' ",1)}

google-sheets regex google-sheets-formula array-formulas google-sheets-query
person Stuck77    schedule 20.07.2019    source источник
comment
Есть ли способ произвольной сортировки данных - я пытаюсь убедиться, что результаты отображаются в таблице в следующем порядке: Контракт | Предложение | Ожидается | CIBS | UBS | Пропущено. Когда я использую запрос регулярного выражения в моем связанном документе, CIBS показывает в моей таблице результатов выше, чем Контракт   -  person Stuck77    schedule 20.07.2019

Ответы (1)


arrow_upward
2
arrow_downward

вы можете использовать регулярное выражение в запросе следующим образом:

=QUERY('2019_MRS Data'!A:W,
 "select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) 
  where E='"&A2&"' 
    and C matches 'Contracted|Proposal|Identified|To Find'
  group by C,G 
  order by C 
  label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)''", 1)

0

объяснение ARRAY_LITERAL ERROR

ОБНОВИТЬ:

=QUERY({IFERROR(QUERY('2019_MRS Data'!A:W,
 "select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) 
  where E='"&A2&"' 
    and C matches 'Contracted'
  group by C,G 
  order by C 
  label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)''", 0),
 {"","","","","","","","","","","","","",""});
 IFERROR(QUERY('2019_MRS Data'!A:W,
 "select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) 
  where E='"&A2&"' 
    and C matches 'Proposal'
  group by C,G 
  order by C 
  label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)''", 0),
 {"","","","","","","","","","","","","",""});
 IFERROR(QUERY('2019_MRS Data'!A:W,
 "select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) 
  where E='"&A2&"' 
    and C matches 'Anticipated'
  group by C,G 
  order by C 
  label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)''", 0),
 {"","","","","","","","","","","","","",""});
 IFERROR(QUERY('2019_MRS Data'!A:W,
 "select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) 
  where E='"&A2&"' 
    and C matches 'CIBS'
  group by C,G 
  order by C 
  label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)''", 0),
 {"","","","","","","","","","","","","",""});
 IFERROR(QUERY('2019_MRS Data'!A:W,
 "select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) 
  where E='"&A2&"' 
    and C matches 'UBS'
  group by C,G 
  order by C 
  label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)''", 0), 
 {"","","","","","","","","","","","","",""});
 IFERROR(QUERY('2019_MRS Data'!A:W,
 "select G,C,sum(L),sum(M),sum(N),sum(O),sum(P),sum(Q),sum(R),sum(S),sum(T),sum(U),sum(V),sum(W) 
  where E='"&A2&"' 
    and C matches 'Missed'
  group by C,G 
  order by C 
  label sum(L)'',sum(M)'',sum(N)'',sum(O)'',sum(P)'',sum(Q)'',sum(R)'',sum(S)'',sum(T)'',sum(U)'',sum(V)'',sum(W)''", 0),
 {"","","","","","","","","","","","","",""})}, "where Col1 is not null", 0)
person player0    schedule 20.07.2019