Перегрузить методы COM-класса методами из стандартного модуля с помощью взлома VTable

Я лишь частично ответил на ваш вопрос. Я по-прежнему считаю, что ключевое слово Me играет роль в предотвращении «перенаправления» метода класса на метод внутри стандартного модуля .bas. Но это применимо только к раннему связыванию.

IDispatch :: Invoke действительно может без проблем вызывать метод внутри модуля .bas. Ваша исходная подпись метода была правильной:

Public Function Meow(ByRef meObj As Class1) As Long

Class1 код:

Option Explicit

Public Sub Meow()
    Debug.Print "Meow"
End Sub

Public Sub Woof()
    Debug.Print "Woof"
End Sub

Код в стандартном модуле .bas:

Option Explicit

Sub Test()
    Dim c As Object 'Must be late-binded!
    Dim vTblPtr As LongPtr
    Dim vTblMeowPtr As LongPtr
    Dim originalMeow As LongPtr
    '
    Set c = New Class1
    c.Meow 'Prints "Meow" to the Immediate Window
    '
    'The address of the virtual table
    vTblPtr = MemLongPtr(ObjPtr(c))
    '
    'The address of the Class1.Meow method within the virtual table
    vTblMeowPtr = vTblPtr + 7 * PTR_SIZE
    '
    'The current address of the Class1.Meow method
    originalMeow = MemLongPtr(vTblMeowPtr)
    '
    'Replace the address of Meow with the one in a .bas module
    MemLongPtr(vTblMeowPtr) = VBA.Int(AddressOf Moew)
    '
    c.Meow 'Prints "Meow in .bas" to the Immediate Window
    '
    'Revert the original address
    MemLongPtr(vTblMeowPtr) = originalMeow
    '
    c.Meow 'Prints "Meow" to the Immediate Window
End Sub

Public Function Moew(ByVal this As Class1) As Long
    Debug.Print "Meow in .bas"
End Function

Я использовал LibMemory для памяти. манипуляции.

Если вы измените метод класса Meow на Function вместо Sub, тогда вам понадобится дополнительный параметр ByRef в конце списка параметров в методе Meow в модуле .bas.

ИЗМЕНИТЬ №1

Я подумал о проблеме, обсуждаемой в комментариях ниже, и единственной причиной, которую я мог придумать, было то, что IDispatch работает только с указателем на интерфейс IUnknown.

Это означает, что:

Public Function Meow(ByRef this As Class1) As Long

приведет к сбою приложения

Но это работает:

Public Function Moew(ByVal this As Class1) As Long
    Debug.Print "Meow in .bas"
End Function

потому что передача ByVal заставляет QueryInterface и AddRef на IUnknown (с Release при выходе из области видимости)

Это тоже работает:

Public Function Moew(ByRef this As IUnknown) As Long
    Debug.Print "Meow in .bas"
End Function

ИЗМЕНИТЬ №2

Приносим извинения за повторную правку.

Метод Invoke не работает с указателем на IUnknown. Он работает с указателем на IDispatch. Это можно проверить с помощью:

Public Function Moew(ByVal this As LongPtr) As Long
    Debug.Print this
    Debug.Print "Meow in .bas"
End Function

который выведет ptr в интерфейс IDispatch. Итак, почему ByRef this As Class1 терпит неудачу? А почему работают ByVal this As Class1 и ByRef this As IUnknown?

ByRef this As Class1
Я считаю, что адрес VarPtr (this) недоступен для VB, поэтому мы читаем память, чего не должны. Это не похоже на то, что в интерфейсе IUnknown есть дополнительные AddRef или Release, потому что метод никогда не вызывается с использованием этого объявления. Приложение просто аварийно завершает работу, когда Invoke пытается вызвать метод.

ByVal this As Class1
Метод просто создает переменную VB (в пространстве памяти VB) и вызывает AddRef.

ByRef this As IUnknown
Поскольку это не двойной интерфейс, выполняется вызов QueryInterface и AddRef. Адрес памяти this находится в пространстве локальной памяти, как и во втором примере.