Правильный способ создания стилей для пользовательских компонентов

Спасибо Рэю Конопке, который отлично рассказал о CodeRage и помог мне ответить на эти вопросы.

Вопрос 1. Можно ли внедрить стиль по умолчанию в компонент?

Да, вы встраиваете стиль по умолчанию, который хотите распространять вместе с компонентом, в ресурс типа RT_RCDATA. Затем просто включите этот ресурс в источник:

{$R *.res}

Примечание. Вам необходимо удалить внешний объект (TLayout), если вы создали его в редакторе макета, прежде чем помещать его в файл res.

Затем переопределите метод GetStyleObject для загрузки стиля из ресурса.

function TLFButton.GetStyleObject: TControl;
var
  S: TResourceStream;
  obj: TLayout;
const
  Style = 'LFButtonStyle';
begin
  result := inherited GetStyleObject;
  if FStyleLookup = 'cornerbuttonstyle' then
  begin
    if FindResource(HInstance, PChar(Style), RT_RCDATA) <> 0 then
    begin
      S := TResourceStream.Create(HInstance, Style, RT_RCDATA);
      try
        obj := TLayout(TStyleManager.LoadFromResource(HInstance, Style, RT_RCDATA));
        //obj := TLayout( CreateObjectFromStream(nil, S) ); << XE2 version
        Result.AddObject(obj);
        Exit;
      finally
        S.Free;
      end;
    end;
  end;
end;

Вопрос 2: Как объединить его со стилем по умолчанию.

В моем случае основой моего компонента был TCornerButton. Я обрезал свой файл .style так, чтобы в нем был только код для дополнительных битов, которые я хотел. В этом случае маленький треугольник указывает на раскрывающуюся кнопку и линию, разделяющую кнопку:

object TLayout
  Align = alRight
  Position.Point = '(76,0)'
  Locked = True
  Width = 15.000000000000000000
  Height = 24.000000000000000000
  object TPath
    StyleName = 'dropdownbutton'
    Align = alCenter
    Position.Point = '(4,9)'
    Width = 8.000000000000000000
    Height = 5.000000000000000000
    HitTest = False
    Fill.Color = claBlack
    Stroke.Kind = bkNone
    Data.Path = {
      04000000000000000000000000000000010000000000803F0000000001000000
      0000003F0000803F030000000000000000000000}
  end
  object TLine
    StyleName = 'dropdownsplit'
    Align = alLeft
    Width = 1.000000000000000000
    Height = 24.000000000000000000
    HitTest = False
    LineType = ltLeft
  end
end

И я помещаю это в ресурс точно таким же образом.

В моем конструкторе я установил StyleLookup как «угловой стиль кнопки».

constructor TLFButton.Create(AOwner: TComponent);
begin
  FStyleLookup := 'cornerbuttonstyle';
  FDropDownButton := false;
  inherited;
end;

Затем я изменяю GetStyleObject так, чтобы он загружал новый материал и добавлял его к существующему стилю.

function TLFButton.GetStyleObject: TControl;
var
  S: TResourceStream;
  obj: TLayout;
const
  Style = 'LFButtonStyle';
begin
  result := inherited GetStyleObject;
  if FStyleLookup = 'cornerbuttonstyle' then
  begin
    if FindRCData(HInstance, Style) then
    begin
      S := TResourceStream.Create(HInstance, Style, RT_RCDATA);
      try
        obj := TLayout( CreateObjectFromStream(nil, S) );
        Result.AddObject(obj);
        Exit;
      finally
        S.Free;
      end;
    end;
  end;
end;

Я надеюсь, что это поможет кому-то еще, и мне было очень трудно получить информацию об этом.

Мартин

Использование: MergeStyle('MyComponent.Style', StyleBook1);

procedure MergeStyle(const aFilename: string; aStyleBook: TStyleBook);
var
  sb: TStyleBook;
  I: Integer;
begin
  sb := TStyleBook.Create(nil);
  try
    sb.FileName := aFilename;

    for I := 0 to sb.Root.ChildrenCount - 1 do
      // Prevent duplicates
      if aStyleBook.Root.FindStyleResource(sb.Root.Children[I].StyleName) = nil then
        aStyleBook.Root.AddObject(sb.Root.Children[I].Clone(aStyleBook.Root));

    aStyleBook.UpdateScenes;
  finally
    sb.Free;
  end;
end;