Вычислить статическое случайное число (вычислить его один раз) в Excel

Вам нужен UDF с памятью, чтобы он знал, изменилась ли ячейка

Этот UDF будет возвращать новое случайное значение при изменении упомянутого вызова, в противном случае возвращает последнее случайное значение (т.е. без изменений). Также возвращает пустое значение, если исходная ячейка пуста (может или не может быть тем, что вам нужно?)

Примечание. Проблема заключается в том, что значения Static теряются при закрытии листа, поэтому значение будет изменяться каждый раз при открытии листа.

Function randonce(r As Range)
    Static trigger As Variant
    Static v As Double
    If r <> trigger Then
        v = Rnd
        trigger = r
    End If
    If Len(r) <> 0 Then
        randonce = v
    Else
        randonce = vbNullString
    End If
End Function

Думаю, у меня есть более простой способ сделать это. Заполните свою электронную таблицу, затем примените функцию = СЛУЧМЕЖДУ для этого столбца чисел. Затем сделайте это:

1. Скопируйте результаты из этого столбца.
2. Выделите столбец и выберите «Специальная вставка» и выберите «Значения».

Теперь у вас есть последние созданные значения, и они статичны.

Вы можете создать UDF (определяемую пользователем функцию):

Public Function Rand_once(ByVal r As Range)
    Rand_once = Rnd
End Function

В ячейку, в которой вы хотите получить результат, вы можете поместить:

=Rand_once(A1)

Значение изменится (фактически, будет пересчитано) только при изменении исходного значения (также известного как A1).

Вы также можете использовать циклические ссылки для создания полностью управляемого формулой «переключателя», позволяющего пользователю вычислять набор случайных чисел, а затем отключать дальнейшие пересчеты. Отключить предупреждения о циклических ссылках, а затем поместите эту формулу в ячейку B3:

=IF($B$1="YES",RAND(),B3)

Если ячейка B1 содержит «ДА», B3 будет генерировать новое случайное число при каждом пересчете электронной таблицы; если B1 содержит любое другое значение, текущее значение B3 будет сохранено.

Это, очевидно, не будет лучшим решением, если вам нужно отслеживать много ячеек, но если вам нужно отслеживать изменения просто A1, вы можете использовать событие для выполнения своей функции в B1, а затем в конец, присвойте ему присвоенное значение. Я считаю это самым простым решением, и оно работает так, как вам нужно.

Пример:

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Address = "$A$1" Then
    With Cells(1, 2)
        .Value = "=rand()" 'or whatever
        .Value = .Value
    End With
End If

End Sub

Declare Function GetCurrentProcessId Lib "kernel32" () As Long
Public Function MySessionRand(Optional seedMod As Single = 0) As Single
    Dim seed As Single
    seed = (-1 * GetCurrentProcessId) - seedMod
    MySessionRand = Rnd(seed)
End Function

Это решение использует текущее значение PID Excel в качестве начального числа. Умножение на -1 приводит к тому, что каждый раз при вызове rnd () используется одно и то же число, поэтому, пока сеанс активен, PID не изменится. 'seedMod' предназначен для помощи функции повторного заполнения, если это необходимо, и может использоваться, например, с. СТРОКА () или КОЛОНКА ().

Public Function MySessionRand2(Optional seed As Single = 0, Optional min As Double = 0, Optional max As Long = 1) As Double
    ' if called with default values will produce either 0 or 1
    If min >= max Then max = min + 1
    MySessionRand2 = Int((max - min + 1) * MySessionRand(seed) + min)
End Function

И дополнительная функция для случайного диапазона.