Можно ли это сделать с помощью обычного XSL?
Да, и XSLT 2.0 предоставляет больше возможностей для обработки текста, чем XSLT 1.0. В XSLT реализована очень сложная обработка текста, включая общий синтаксический анализатор LR(1), используемый для создания синтаксических анализаторов для конкретные грамматики, такие как JSON и XPath.
В частности, узнайте о unparsed-text(), различные строковые функции< /strong>, включая те, которые позволяют использовать регулярные выражения (matches()< /a>, tokenize() и replace()), а также инструкция <xsl:analyze-string> .
XSLT 1.0 также имеет строковые функции (предусмотренные XPath 1.0), однако ему не хватает возможностей/функций регулярных выражений, и нет ничего подобного функции XSLT 2.0 unparsed-text(). Среди наиболее полезных строковых функций XPath 1.0: substring(), substring-before(), substring-after(), starts-with(), string-length(), concat() и особенно translate().
Можно «прочитать» файл, используя объект в DTD, как объяснил Мэдс Хансен в своем ответе. Другой способ — прочитать файл в программе, которая инициирует преобразование, а затем передать содержимое файла в виде строкового параметра преобразованию.
Обновление: теперь ОП предоставила конкретные данные, так что возможно полное решение:
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:variable name="vText" select=
"unparsed-text('file:///c:/temp/delete/test.ini')"/>
<xsl:variable name="vLines" as="xs:string*" select=
"tokenize($vText, '
?
')[.]"/>
<xsl:variable name="vLineCnt" select="count($vLines)"/>
<xsl:variable name="vSectLinesInds" as="xs:integer*" select=
"for $i in 1 to $vLineCnt
return
if(starts-with(normalize-space($vLines[$i]), '['))
then $i
else ()
"/>
<xsl:variable name="vSectCnt" select="count($vSectLinesInds)"/>
<xsl:template match="/">
<xsl:for-each select="$vSectLinesInds">
<xsl:variable name="vPos" select="position()"/>
<xsl:variable name="vInd" as="xs:integer" select="."/>
<xsl:variable name="vthisLine" as="xs:string"
select="$vLines[$vInd]"/>
<xsl:variable name="vNextSectInd" select=
"if($vPos eq $vSectCnt)
then
$vLineCnt +1
else
$vSectLinesInds[$vPos +1]
"/>
<xsl:variable name="vInnerLines" select=
"$vLines
[position() gt current()
and
position() lt $vNextSectInd
]
"/>
<xsl:variable name="vName" select=
"tokenize($vthisLine, '\[|\]')[2]"/>
<xsl:element name="{$vName}">
<xsl:for-each select="$vInnerLines">
<xsl:variable name="vInnerParts" select=
"tokenize(., '[ ]*=[ ]*')"/>
<xsl:element name="{$vInnerParts[1]}">
<xsl:value-of select="$vInnerParts[2]"/>
</xsl:element>
</xsl:for-each>
</xsl:element>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
когда это преобразование применяется к любому XML-документу (не используется) и если файл в C:\temp\delete\test.ini имеет следующее содержимое:
[section1]
option1 = values1
option2 = values2
option3 = values3
option4 = values4
option5 = values5
[section2]
option1 = values1
option2 = values2
option3 = values3
option4 = values4
option5 = values5
[section3]
option1 = values1
option2 = values2
option3 = values3
option4 = values4
option5 = values5
получен желаемый правильный результат:
<section1>
<option1>values1</option1>
<option2>values2</option2>
<option3>values3</option3>
<option4>values4</option4>
<option5>values5</option5>
</section1>
<section2>
<option1>values1</option1>
<option2>values2</option2>
<option3>values3</option3>
<option4>values4</option4>
<option5>values5</option5>
</section2>
<section3>
<option1>values1</option1>
<option2>values2</option2>
<option3>values3</option3>
<option4>values4</option4>
<option5>values5</option5>
</section3>
person
Dimitre Novatchev
schedule
08.12.2011
{}. - person Dimitre Novatchev schedule 08.12.2011