Как закодировать кнопку для получения данных из таблицы в базе данных и отображения в представлении сетки данных?

Я уверен, что есть много способов сделать это, но попробуйте это. Допустим, у вас есть база данных с таблицей с именем «TestSample», в которой есть три столбца с именами «Column1», «Column2», «Column3». Затем добавьте элемент управления ListView в форму и назовите его «ListDisplay» и, возможно, две кнопки для тестирования. Затем вам нужно создать столбцы, вы можете сделать это с помощью кода, подобного этому

Private Sub CreateColumns()
    'ListDisplay is the name of the ListView Control'
    ListDisplay.View = View.Details
    ListDisplay.FullRowSelect = True

    'Create Columns'
    ListDisplay.Columns.Add("Column1", 200, HorizontalAlignment.Left)
    ListDisplay.Columns.Add("Column2", 200, HorizontalAlignment.Left)
    ListDisplay.Columns.Add("Column3", 200, HorizontalAlignment.Left)
End Sub

этот код можно вызвать из события «Загрузка формы», например

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    'Setup Colums'
    CreateColumns()
End Sub

Следующее, что нужно сделать, это собрать данные из базы данных и вставить обратно в базу данных. Эти две функции могут помочь.

 Private Sub FillTable(ByVal connString As String, ByVal QueryString As String)
    'Clear Populated Items'
    ListDisplay.Items.Clear()

    'Setup Connection and query'
    Dim conn As SqlConnection = New SqlConnection(connString)
    Dim cmd As SqlCommand = New SqlCommand(QueryString, conn)
    Dim da As SqlDataAdapter = New SqlDataAdapter(cmd)

    'Setup Dataset'
    Dim ds As New DataSet

    'Populate Dataset'
    conn.Open()
    da.Fill(ds, "TestSample")
    conn.Close()

    'Free up memory'
    cmd.Dispose()
    conn.Dispose()

    'Populate ListView Control'
    For Each dr As DataRow In ds.Tables("TestSample").Rows
        Dim items As New ListViewItem
        items.Text = dr.Item(0).ToString()
        items.SubItems.Add(dr.Item(1).ToString())
        items.SubItems.Add(dr.Item(2).ToString())

        ListDisplay.Items.Add(items)
    Next

End Sub

Private Sub InsertBack(ByVal connString As String, ByVal QueryString As String, ByVal ParameterOne As String, ByVal ParameterTwo As String, ByVal ParameterThree As String)
    'Setup Connection'
    Dim conn As SqlConnection = New SqlConnection(connString)
    Dim cmd As SqlCommand = New SqlCommand(QueryString, conn)

    'Setup Parameters'
    cmd.Parameters.Add("@Column1", SqlDbType.Text).Value = ParameterOne
    cmd.Parameters.Add("@Column2", SqlDbType.Text).Value = ParameterTwo
    cmd.Parameters.Add("@Column3", SqlDbType.Text).Value = ParameterThree

    'Process data: Insert to database'
    conn.Open()
    cmd.ExecuteNonQuery()
    conn.Close()

    'Free up memory'
    cmd.Dispose()
    conn.Dispose()

End Sub

используя кнопку «Click Event» в форме, которую вы можете вызвать, заполните ListView следующим образом

 'Get data from database and populate ListView: Parameter requires connection string'
    FillTable("Data Source=SERVER-PC;Initial Catalog=Database;Persist Security Info=True;User ID=UsernameIfRequired;Password=PasswordIfRequired", "SELECT * FROM TestSample")

строка подключения является образцом, вам нужно будет предоставить свою собственную, а также строку запроса необходимо будет изменить в соответствии с вашей базой данных. Наконец, чтобы вставить данные в базу данных, скажем, из ваших элементов ListView, если они были изменены, вы можете сделать это как ...

  'Loop through all Items in the ListView and send to database'
    For Each item As ListViewItem In ListDisplay.Items
        'Add data to the database from ListView Items: Parameter requres connection string and the 3 input items (could be as many as you want)'
        InsertBack("Data Source=SERVER-PC;Initial Catalog=Database;Persist Security Info=True;User ID=UsernameIfRequired;Password=PasswordIfRequired", "INSERT INTO TestSample (Column1,Column2,Column3) values (@Column1,@Column2,@Column3)", item.Text, item.SubItems(1).Text, item.SubItems(2).Text)

        'Add data to the database from ListView Items: Parameter requres connection string and the 3 input items (could be as many as you want)'
        InsertBack("Data Source=SERVER-PC;Initial Catalog=Database;Persist Security Info=True;User ID=UsernameIfRequired;Password=PasswordIfRequired", "INSERT INTO AnotherSample (Column1,Column2,Column3) values (@Column1,@Column2,@Column3)", item.Text, item.SubItems(1).Text, item.SubItems(2).Text)
    Next

Как видите, данные можно отправить в две разные таблицы.

Почему бы просто не скопировать первую таблицу во вторую, а затем привязать gridview ко второй таблице вместо того, чтобы пытаться привязать gridview к обоим?