Delphi + Synapse: как проверить размер ответа с помощью TTCPBlockSocket

Попробуйте следующий код. Он показывает, как получить Content-Length из заголовка ответа и прочитать само содержимое.

Обратите внимание, что протокол HTTP далеко не так прост, но если вы собираетесь общаться со своим собственным сервером или с сервером, где вы знаете, как он работает, вы можете взять это как вдохновение. И не забудьте включить OpenSSL (версия 0.9.8, безусловно, совместима с Synapse) при использовании этого кода.

uses
  blcksock, ssl_openssl;

function HTTPGetText(const Host: string): AnsiString;
var
  ContentLength: Integer;
  HTTPHeader: AnsiString;      
  TCPSocket: TTCPBlockSocket;
begin
  Result := '';

  TCPSocket := TTCPBlockSocket.Create;
  try
    // initialize TTCPBlockSocket
    TCPSocket.ConvertLineEnd := True;
    TCPSocket.SizeRecvBuffer := c64k;
    TCPSocket.SizeSendBuffer := c64k;

    // connect to the host, port 443 is default for HTTP over SSL
    TCPSocket.Connect(Host, '443');
    // check for socket errors
    if TCPSocket.LastError <> 0 then
      Exit;

    // server name identification
    TCPSocket.SSL.SNIHost := Host;
    // initialize and connect over OpenSSL
    TCPSocket.SSLDoConnect;
    // server name identification
    TCPSocket.SSL.SNIHost := '';
    // check for socket errors
    if TCPSocket.LastError <> 0 then
      Exit;

    // build the HTTP request header
    HTTPHeader :=
      'GET / HTTP/1.0' + CRLF +
      'Host: ' + Host + ':443' + CRLF +
      'Keep-Alive: 300' + CRLF +
      'Connection: keep-alive' + CRLF +
      'User-Agent: Mozilla/4.0' + CRLF + CRLF;

    // send the HTTP request
    TCPSocket.SendString(HTTPHeader);
    // check for socket errors
    if TCPSocket.LastError <> 0 then
      Exit;

    // read the response status, here some servers might give you the content
    // note, that we are waiting in a loop until the timeout or another error
    // occurs; if we get some terminated line, we break the loop and continue
    // to check if that line is the HTTP status code
    repeat
      HTTPHeader := TCPSocket.RecvString(5000);
      if HTTPHeader <> '' then
        Break;
    until
      TCPSocket.LastError <> 0;

    // if the line we've received is the status code, like 'HTTP/1.1 200 OK'
    // we will set the default value for content length to be read
    if Pos('HTTP/', HTTPHeader) = 1 then
    begin
      ContentLength := -1;

      // read the response header lines and if we find the 'Content-Length' we
      // will store it for further content reading; note, that again, we are
      // waiting in a loop until the timeout or another error occurs; if the
      // empty string is received, it means we've read the whole response header
      repeat
        HTTPHeader := TCPSocket.RecvString(5000);
        if Pos('Content-Length:', HTTPHeader) = 1 then
          ContentLength := StrToIntDef(Trim(Copy(HTTPHeader, 16, MaxInt)), -1);
        if HTTPHeader = '' then
          Break;
      until
        TCPSocket.LastError <> 0;

      // and now let's get the content, we know it's size, so we just call the
      // mentioned RecvBufferStr function
      if ContentLength <> -1 then
        Result := TCPSocket.RecvBufferStr(ContentLength, 5000);
    end;

    TCPSocket.CloseSocket;

  finally
    TCPSocket.Free;
  end;
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
  Memo1.Text := HTTPGetText('www.meebo.com');
end;

При повторном тестировании WaitingDataEx, как упомянул TLama, я решил поместить строку, выводящую WaitingDataEx, после RecvBufferStr.

IntToStr(WaitingDataEx) работал и отображал оставшиеся данные.

WaitingDataEx проверяет наличие ожидающих данных в этот конкретный момент, и поскольку реальной паузы между отправкой данных и их поиском не было, он увидел, что данных для получения еще нет.

Я решил проблему с помощью следующего кода:

httpRsp := httpRsp + Socket.RecvBufferStr(1, 25000);
httpRsp := httpRsp + Socket.RecvBufferStr(Socket.WaitingDataEx, 100); 

1. Это ожидает получения 1 байта данных, а затем добавляет эти данные к строковой переменной httpRsp.
2. Затем он использует Socket.WaitingDataEx для чтения остальных байтов, поскольку первая команда RecvBufferStr уже выполнила ожидание, чтобы убедиться, что есть байты для получения.

ИЗМЕНИТЬ выше

Приведенный выше код сломался на определенном сервере, с которым я общаюсь, хотя я не уверен, почему. Он будет получать только заголовки, а не контент с одного сервера, с которым я общаюсь. Я решил проблему с помощью кода ниже:

httpRsp := httpRsp + Socket.RecvPacket(50000);
while Socket.WaitingDataEx > 0 do
  httpRsp := httpRsp + Socket.RecvPacket(50000);